Code: Select all

// This Pine Script™ code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © AlgoAlpha

//@version=6
indicator("Smart Money Volume Index [AlgoAlpha]", "AlgoAlpha - Smart Money", explicit_plot_zorder = true, behind_chart=false)
mode = input.string("Net", "Display Mode", options = ["Compare", "Net"], group = "Settings", tooltip = "Choose between 'Compare' to see buy/sell interest separately, or 'Net' for a single oscillator.")
x = input.int(25, "Index Period", minval = 1, group = "Settings", tooltip = "Length of the summation period for the interest index.")
rr = input.int(14, "Volume Flow Period", minval = 1, group = "Settings", tooltip = "RSI period applied to the volume flow calculations.")
peakslen = input.int(500, "Normalization Period", minval = 1, group = "Settings", tooltip = "Lookback period for finding the peak value to normalize the index.")
thr = input.float(0.9, "High Interest Threshold", minval = 0.01, maxval = 0.99, step = 0.05, group = "Settings", tooltip = "Level at which interest is considered 'High'. Triggers alerts and highlights.")

green = input.color(#00ffbb, "Up Color", group = "Colors", tooltip = "Main color for Buying Interest.")
sec_green = input.color(#008461, "Secondary Up Color", group = "Colors", tooltip = "Secondary color for Net Buy layers.")
red = input.color(#ff1100, "Down Color", group = "Colors", tooltip = "Main color for Selling Interest.")
sec_red = input.color(#840900, "Secondary Down Color", group = "Colors", tooltip = "Secondary color for Net Sell layers.")

dumb = ta.pvi-ta.ema(ta.pvi,255)
smart = ta.nvi-ta.ema(ta.nvi,255)

drsi = ta.rsi(dumb, rr)
srsi = ta.rsi(smart, rr)

r_buy = srsi / drsi //ratio shows if smart money is buying from dumb money selling
r_sell = (100 - srsi) / (100 - drsi) //ratio shows if dumb money is buying from smart money selling

sums_buy = math.sum(r_buy, x)
sums_sell = math.sum(r_sell, x)
peak = ta.highest(math.max(sums_buy, sums_sell), peakslen)

index_buy = sums_buy / peak
index_sell = sums_sell / peak
net_index = index_buy - index_sell

bottom = plot(0, "Zero Line", color = color.gray)
top = plot(1, "Top Limit", display = display.none)
low_ = plot(-1, "Bottom Limit", display = display.none)

thresh_up = plot(thr, "High Buy Threshold", display = display.none)
thresh_down = plot(-thr, "High Sell Threshold", display = display.none)

plot_buy = mode == "Compare" ? index_buy : na
plot_sell = mode == "Compare" ? -index_sell : na

i_buy = plot(plot_buy, "Buy Interest", color = green, style = plot.style_linebr)
i_sell = plot(plot_sell, "Sell Interest", color = red, style = plot.style_linebr)

// Net Mode Layered Columns
transp = 20
n_up = mode == "Net" and net_index > 0 ? net_index : na
n_dn = mode == "Net" and net_index < 0 ? net_index : na

plot(n_up, "Net Buy 100", color = color.new(sec_green, transp + 60), style = plot.style_columns, linewidth = 4)
plot(n_up * 0.8, "Net Buy 80", color = color.new(sec_green, transp + 55), style = plot.style_columns, linewidth = 4)
plot(n_up * 0.6, "Net Buy 60", color = color.new(sec_green, transp + 45), style = plot.style_columns, linewidth = 4)
plot(n_up * 0.4, "Net Buy 40", color = color.new(sec_green, transp + 30), style = plot.style_columns, linewidth = 4)
plot(n_up * 0.2, "Net Buy 20", color = color.new(sec_green, transp + 25), style = plot.style_columns, linewidth = 4)

plot(n_up, "Net Buy Line", color = color.new(green, transp), style = plot.style_linebr)

plot(n_dn, "Net Sell 100", color = color.new(sec_red, transp + 60), style = plot.style_columns, linewidth = 4)
plot(n_dn * 0.8, "Net Sell 80", color = color.new(sec_red, transp + 55), style = plot.style_columns, linewidth = 4)
plot(n_dn * 0.6, "Net Sell 60", color = color.new(sec_red, transp + 45), style = plot.style_columns, linewidth = 4)
plot(n_dn * 0.4, "Net Sell 40", color = color.new(sec_red, transp + 30), style = plot.style_columns, linewidth = 4)
plot(n_dn * 0.2, "Net Sell 20", color = color.new(sec_red, transp + 25), style = plot.style_columns, linewidth = 4)

plot(n_dn, "Net Sell Line", color = color.new(red, transp), style = plot.style_linebr)

v_up = mode == "Compare" ? index_buy : net_index
v_dn = mode == "Compare" ? -index_sell : net_index
top_active = v_up > 0.7
bot_active = v_dn < -0.7

fill(thresh_up, top, 1, thr, top_active ? color.new(chart.fg_color, 45) : color.new(chart.fg_color, 90), top_active ? color.new(chart.fg_color, 30) : color.new(chart.fg_color, 60))
fill(thresh_down, low_, -thr, -1, bot_active ? color.new(chart.fg_color, 30) : color.new(chart.fg_color, 60), bot_active ? color.new(chart.fg_color, 45) : color.new(chart.fg_color, 90))

fill(bottom, i_buy, plot_buy, 0, green, chart.bg_color)
fill(bottom, i_sell, plot_sell, 0, red, chart.bg_color)

sig_buy = mode == "Compare" ? index_buy : net_index
sig_sell = mode == "Compare" ? index_sell : -net_index

abs_net = math.abs(net_index)
net_color = net_index > 0 ? color.from_gradient(abs_net, 0, 1, chart.bg_color, green) : color.from_gradient(abs_net, 0, 1, chart.bg_color, red)
comp_color = sig_buy > thr ? green : sig_sell > thr ? red : na

candle_color = mode == "Net" ? net_color : comp_color
plotcandle(open, high, low, close, "Smart Money Candles", color = candle_color, wickcolor = candle_color, bordercolor = candle_color, force_overlay = true)
plot(close, "Price Tracking line", color = color.new(chart.fg_color, 85), force_overlay = true)

///Alerts
alertcondition(ta.crossover(sig_buy, thr), "High Smart Money Buy Interest")
alertcondition(ta.crossover(sig_sell, thr), "High Smart Money Sell Interest")
alertcondition(ta.crossunder(sig_buy, thr), "Smart Money Buy Interest no longer high")
alertcondition(ta.crossunder(sig_sell, thr), "Smart Money Sell Interest no longer high")
alertcondition(ta.crossover(sig_buy, 0), "Smart Money Buy Interest turned positive")
alertcondition(ta.crossunder(sig_buy, 0), "Smart Money Buy Interest turned negative")
alertcondition(ta.crossover(sig_sell, 0), "Smart Money Sell Interest turned positive")
alertcondition(ta.crossunder(sig_sell, 0), "Smart Money Sell Interest turned negative")
alertcondition(ta.crossover(v_up, 0.7), "Smart Money Buy Interest entered high zone")
alertcondition(ta.crossunder(v_up, 0.7), "Smart Money Buy Interest exited high zone")

Code: Select all

// This work is licensed under a Attribution-NonCommercial-ShareAlike 4.0 International (CC BY-NC-SA 4.0) https://creativecommons.org/licenses/by-nc-sa/4.0/
// © Zeiierman {

//@version=5
indicator('AI Trend Navigator', overlay=true)

// ~~ Tooltips {
t1 ="PriceValue selects the method of price computation. \n\nSets the smoothing period for the PriceValue. \n\nAdjusting these settings will change the input values for the K-Nearest Neighbors algorithm, influencing how the trend is calculated."
t2 = "TargetValue specifies the target to evaluate. \n\nSets the smoothing period for the TargetValue."
t3 ="numberOfClosestValues sets the number of closest values that are considered when calculating the KNN Moving Average. Adjusting this number will affect the sensitivity of the trend line, with a higher value leading to a smoother line and a lower value resulting in a line that is more responsive to recent price changes."
t4 ="smoothingPeriod sets the period for the moving average applied to the KNN classifier. Adjusting the smoothing period will affect how rapidly the trend line responds to price changes, with a larger smoothing period leading to a smoother line that may lag recent price movements, and a smaller smoothing period resulting in a line that more closely tracks recent changes."
t5 ="This option controls the background color for the trend prediction. Enabling it will change the background color based on the prediction, providing visual cues on the direction of the trend. A green color indicates a positive prediction, while red indicates a negative prediction."
//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~}

// ~~ Inputs {
PriceValue   = input.string("hl2", options = ["hl2","VWAP", "sma", "wma", "ema", "hma"], group="", inline="Value")
maLen        = input.int(5, minval=2, maxval=200, title="", group="", inline="Value", tooltip=t1)
TargetValue  = input.string("Price Action", options = ["Price Action","VWAP", "Volatility", "sma", "wma", "ema", "hma"], group="", inline="Target")
maLen_       = input.int(5, minval=2, maxval=200, title="", group="", inline="Target", tooltip=t2)
// Input parameters for the KNN Moving Average
numberOfClosestValues = input.int(3, "Number of Closest Values", 2, 200, tooltip=t3) 
smoothingPeriod       = input.int(50, "Smoothing Period", 2, 500, tooltip=t4) 
windowSize            = math.max(numberOfClosestValues, 30) 

// knn Color
Upknn_col   = input.color(color.lime, title="", group="KNN Color", inline="knn col")
Dnknn_col   = input.color(color.red, title="", group="KNN Color", inline="knn col")
Neuknn_col  = input.color(color.orange, title="", group="KNN Color", inline="knn col")
// MA knn Color
Maknn_col   = input.color(color.teal, title="", group="MA KNN Color", inline="MA knn col")
// BG Color
bgcolor = input.bool(false, title="Trend Prediction Color", group="BG Color", inline="bg", tooltip=t5)
Up_col  = input.color(color.lime, title="", group="BG Color", inline="bg")
Dn_col  = input.color(color.red, title="", group="BG Color", inline="bg")
//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~}

// ~~ kNN Classifier {
value_in = switch PriceValue
    "hl2"  => ta.sma(hl2,maLen)
    "VWAP" => ta.vwap(close[maLen])
    "sma" => ta.sma(close,maLen)
    "wma" => ta.wma(close,maLen)
    "ema" => ta.ema(close,maLen)
    "hma" => ta.hma(close,maLen)

meanOfKClosest(value_,target_) => 
    closestDistances = array.new_float(numberOfClosestValues, 1e10) 
    closestValues    = array.new_float(numberOfClosestValues, 0.0) 
    for i = 1 to windowSize 
        value = value_[i] 
        distance = math.abs(target_ - value) 
        maxDistIndex = 0 
        maxDistValue = closestDistances.get(0) 
        for j = 1 to numberOfClosestValues - 1 
            if closestDistances.get(j) > maxDistValue
                maxDistIndex := j
                maxDistValue := closestDistances.get(j)
        if distance < maxDistValue 
            closestDistances.set(maxDistIndex, distance)
            closestValues.set(maxDistIndex, value)
    closestValues.sum() / numberOfClosestValues 

// Choose the target input based on user selection
target_in = switch TargetValue
    "Price Action"  => ta.rma(close,maLen_) 
    "VWAP"          => ta.vwap(close[maLen_])
    "Volatility"    => ta.atr(14)
    "sma" => ta.sma(close,maLen_)
    "wma" => ta.wma(close,maLen_)
    "ema" => ta.ema(close,maLen_)
    "hma" => ta.hma(close,maLen_)

knnMA = meanOfKClosest(value_in,target_in)
//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~}

// ~~ kNN Prediction {
// Function to calculate KNN Classifier
price = math.avg(knnMA, close)
c     = ta.rma(knnMA[1], smoothingPeriod) 
o     = ta.rma(knnMA, smoothingPeriod)

// Defines KNN function to perform classification
knn(price) => 
    Pos_count = 0 
    Neg_count = 0 
    min_distance = 10e10 
    nearest_index = 0 
    for j = 1 to 10 
        distance = math.sqrt(math.pow(price[j] - price, 2)) 
        if distance < min_distance 
            min_distance := distance
            nearest_index := j
            Neg = c[nearest_index] > o[nearest_index] 
            Pos = c[nearest_index] < o[nearest_index] 
            if Pos 
                Pos_count += 1
            if Neg 
                Neg_count += 1
    output = Pos_count>Neg_count?1:-1 

// Calls KNN function and smooths the prediction
knn_prediction_raw = knn(price) 
knn_prediction     = ta.wma(knn_prediction_raw, 3)
//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~}

// ~~ Plots {
// Plots for display on the chart
knnMA_          = ta.wma(knnMA,5)
knnMA_col       = knnMA_>knnMA_[1]?Upknn_col:knnMA_<knnMA_[1]?Dnknn_col:Neuknn_col
Classifier_Line = plot(knnMA_,"Knn Classifier Line", knnMA_col)
MAknn_          = ta.rma(knnMA, smoothingPeriod)
plot(MAknn_,"Average Knn Classifier Line" ,Maknn_col) 
green = knn_prediction < 0.5
red   = knn_prediction > -0.5 
bgcolor( green and bgcolor? color.new(Dn_col,80) : 
 red and bgcolor ? color.new(Up_col,80) : na) 
//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~}

// ~~ Alerts {
knnMA_cross_Over_Ma      = ta.crossover(knnMA_,MAknn_)
knnMA_cross_Under_Ma     = ta.crossunder(knnMA_,MAknn_)
knnMA_cross_Over_Close   = ta.crossover(knnMA_,close)
knnMA_cross_Under_Close  = ta.crossunder(knnMA_,close)
knnMA_Switch_Up          = knnMA_[1]<knnMA_ and knnMA_[1]<=knnMA_[2]
knnMA_Switch_Dn          = knnMA_[1]>knnMA_ and knnMA_[1]>=knnMA_[2]
knnMA_Neutral            = knnMA_col==Neuknn_col and knnMA_col[1]!=Neuknn_col
greenBG                  = green and not green[1]
redBG                    = red and not red[1]

alertcondition(knnMA_cross_Over_Ma,  title = "Knn Crossover Average Knn",  message = "Knn Crossover Average Knn")
alertcondition(knnMA_cross_Under_Ma, title = "Knn Crossunder Average Knn", message = "Knn Crossunder Average Knn")
alertcondition(knnMA_cross_Over_Close,  title = "Knn Crossover Close",  message = "Knn Crossover Close")
alertcondition(knnMA_cross_Under_Close, title = "Knn Crossunder Close", message = "Knn Crossunder Close")
alertcondition(knnMA_Switch_Up,  title = "Knn Switch Up",  message = "Knn Switch Up")
alertcondition(knnMA_Switch_Dn, title = "Knn Switch Dn", message = "Knn Switch Dn")
alertcondition(knnMA_Neutral, title = "Knn is Neutral", message = "Knn is Neutral")
alertcondition(greenBG, title = "Positive Prediction", message = "Positive Prediction")
alertcondition(redBG, title = "Negative Prediction", message = "Negative Prediction")
//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~}