mrtools wrote: Sat May 13, 2023 8:18 am Don't worry, it took me longer than I care to admit to figure it out

This script helps you identify the relative strength of bulls and bears in the market. It calculates the difference between the high and the moving average for bulls, and the difference between the moving average and the low for bears.

Then it normalizes the values between -100 and 100 using the highest and lowest values of the last "bars back" periods. This allows you to compare the current strength of bulls and bears relative to their historical strength.

The output of the script is a colored column chart that represents the difference between the normalized bulls and bears values. If the chart is mostly green, it means the bulls are currently stronger than the bears, and vice versa for a mostly red chart.

Additionally, the script provides bullish and bearish signals based on when the normalized bulls cross above or below the user-defined "Line Height" value. You can use this script to help you identify potential trend changes in the market, as well as to confirm existing trends.

//@version=4
study("Bulls v Bears")

// Input settings
len = input(title="BvB Period", type=input.integer, defval=14, minval=1)
bars_back = input(title="Nomralized bars back", type=input.integer, defval=120, minval=1)
tline = input(80, title="Line Height" )

// Calculation
ma = ema(close, len)
bulls = high - ma
bears = ma - low

// Normalize the values between -100 and 100
min_bulls = lowest(bulls, bars_back)
max_bulls = highest(bulls, bars_back)
norm_bulls = ((bulls - min_bulls) / (max_bulls - min_bulls) - 0.5) * 100

min_bears = lowest(bears, bars_back)
max_bears = highest(bears, bars_back)
norm_bears = ((bears - min_bears) / (max_bears - min_bears) - 0.5) * 100

// Calculate the total and add signals
total = norm_bulls - norm_bears
bullish_o = total > tline
bearish_o = total < -tline

// Plot the total with colored columns
col = total >= 0 ? color.green : color.red
plot(total, color=col, style=plot.style_columns, title="BvB")
plotshape(bullish_o, style=shape.circle, location=location.top, color=#ff00d4, title="Bullish Crossover")
plotshape(bearish_o, style=shape.circle, location=location.bottom, color=#eeff00, title="Bearish Crossover")

// Horizontal lines
hline(tline, color=color.gray)
hline(-tline, color=color.gray)

// Alerts
alertcondition(bullish_o, title="Bullish Crossover", message="Bullish overbought")
alertcondition(bearish_o, title="Bearish Crossover", message="Bearish oversold")
alertcondition(crossover(total, 0), title="Total Crossover", message="BvB total crossover")

TransparentTrader wrote: Sun May 14, 2023 11:44 am Bulls Vs Bears, Normalized [TradingView]

kvak or mrtools, I have an idea for the normal Bulls Vs Bears indicator that can also be applied to other indicators.

What's featured here is a normalized version of Bulls Vs Bears created by TradingView user Mihkel00.

ffsss wrote: Sun May 14, 2023 9:32 pm How would you avoid these situations and determine if a trend is valid?
Looks good overall.

ffsss wrote: Sun May 14, 2023 9:32 pm How would you avoid these situations and determine if a trend is valid?
Looks good overall.

TransparentTrader wrote: Mon May 15, 2023 1:31 am It's a good question, and ranging markets always throw us off. I'm thinking this Bulls Vs Bears indicator could be used as a form of secondary trend confirmation. For primary trend confirmation I would use a separate indicator.

I would personally use the normalized Bulls Vs Bears for finding tops and bottoms more than I would for finding trends.

GoldenBrett90 wrote: Mon May 15, 2023 1:55 pm Dear MrTools...
This is simple and very effective, but I don't think it has been done....
Can you please make a 4TF 50-line-cross OMA RSI?