//+------------------------------------------------------------------+
//|                                                    alb - RSI.mq4 |
//+------------------------------------------------------------------+
#property copyright "mladen"
#property link      "mladenfx@gmail.com"

#property indicator_separate_window
#property indicator_buffers    3
#property indicator_minimum    0
#property indicator_maximum    100
#property indicator_color1     DeepSkyBlue
#property indicator_width1     2
#property indicator_color2     OrangeRed
#property indicator_style2     STYLE_DASH
#property indicator_color3     Gold
#property indicator_levelcolor DarkSlateGray

//
//
//
//
//

extern string TimeFrame        = "Current time frame";
extern int    swingCount       = 5;
extern int    RsiPrice         = PRICE_CLOSE;
extern int    RsiMethod        = 0;
extern double speed            = 1.00;
extern int    FastMaPeriod     = 7;
extern int    FastMa_Mode      = MODE_LWMA;
extern int    SlowMaPeriod     = 34;
extern int    SlowMa_Mode      = MODE_LWMA;
extern int    SmoothLength     = 5;
extern double SmoothPhase      = 0;
extern bool   SmoothDouble     = true;
extern double levelOs          = 25.00;
extern double levelOb          = 75.00; 
extern bool   Interpolate      = true;

extern bool   alertsOn         = true;
extern bool   alertsOnCurrent  = false;
extern bool   alertsMessage    = true;
extern bool   alertsSound      = true;
extern bool   alertsEmail      = false;
 
extern bool   ShowArrows       = true;
extern string arrowsIdentifier = "albspeedrsi";
extern color  arrowsUpColor    = LimeGreen;
extern color  arrowsDnColor    = Red;

//
//
//
//
//

double swingBuffer[];
double rsiBuffer[];
double fastma[];
double slowma[];
double trend[];

//
//
//
//
//

string indicatorFileName;
bool   calculateValue;
bool   returnBars;
int    timeFrame;

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int init()
{
   IndicatorBuffers(5);
   SetIndexBuffer(0,rsiBuffer);
   SetIndexBuffer(1,fastma);
   SetIndexBuffer(2,slowma);
   SetIndexBuffer(3,swingBuffer);
   SetIndexBuffer(4,trend);
   
      speed = MathMax(speed,0.000001);
      SetLevelValue(0,levelOs);
      SetLevelValue(1,levelOb);
      
      //
      //
      //
      //
      //
    
      indicatorFileName = WindowExpertName();
      calculateValue    = (TimeFrame=="calculateValue"); if (calculateValue) return(0);
      returnBars        = (TimeFrame=="returnBars");     if (returnBars)     return(0);
      timeFrame         = stringToTimeFrame(TimeFrame);
      
      //
      //
      //
      //
      //
   
      IndicatorShortName(timeFrameToString(timeFrame)+"  alb of smoothed "+getRsiName(RsiMethod)+"  ("+FastMaPeriod+","+SlowMaPeriod+")");
 return(0);
}

//
//
//
//
//

int deinit() { Comment(""); if (!calculateValue && ShowArrows) deleteArrows(); return(0);}

//+-----------------------------------------------------------------------------------------------------------------------------+
//|                                                                                                                             |
//+-----------------------------------------------------------------------------------------------------------------------------+
//
//
//
//
//

int start()
{
   int counted_bars=IndicatorCounted();
   int i,x,s,limit;

   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
         limit = MathMin(Bars-counted_bars,Bars-1);
          if (returnBars) { rsiBuffer[0] = limit+1; return(0); }
    
   //
   //
   //
   //
   //
   
   if (calculateValue || timeFrame==Period())
   {
             
   for(i=limit; i>=0; i--)
   {
      int swing = 0;
         if (High[i]>High[i+1] && High[i+1]>High[i+2] && Low[i+2] < Low[i+3] && Low[i+3] < Low[i+4]) swing = -1;
         if (Low[i] < Low[i+1] && Low[i+1] < Low[i+2] && High[i+2]>High[i+3] && High[i+3]>High[i+4]) swing =  1;
      swingBuffer[i] = swing;
   
      //
      //
      //
      //
      //
      
      int k = i;
      int n = 0;
         for (; (k<Bars) && (n<swingCount); k++) if(swingBuffer[k]!=0) n++;
               double albPeriod = MathMax(MathRound((k-i)/swingCount/speed),1);
               
      rsiBuffer[i] = iDSmooth(iRsi(getPrice(RsiPrice,i),albPeriod,i,0,RsiMethod),SmoothLength,SmoothPhase,SmoothDouble,i); 
      
      }
      
      //
      //
      //
      //
      // 
      
      for(i=limit; i>=0; i--)
      {
      
      fastma[i] = iMAOnArray(rsiBuffer,Bars,FastMaPeriod,0,FastMa_Mode,i); 
      slowma[i] = iMAOnArray(rsiBuffer,Bars,SlowMaPeriod,0,SlowMa_Mode,i); 
      trend[i]= trend[i+1];
                          
           if (rsiBuffer[i] > fastma[i] && rsiBuffer[i] > slowma[i]) trend[i] =  1;
           if (rsiBuffer[i] < fastma[i] && rsiBuffer[i] < slowma[i]) trend[i] = -1;
           if (!calculateValue) manageArrow(i);
      }
      manageAlerts();
      return (0);
   }
          
   //
   //
   //
   //
   //
    
   limit = MathMax(limit,MathMin(Bars,iCustom(NULL,timeFrame,indicatorFileName,"returnBars",0,0)*timeFrame/Period()));
     
   for (i=limit; i>=0; i--)
   {
       int y = iBarShift(NULL,timeFrame,Time[i]);
            rsiBuffer[i]  = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",swingCount,RsiPrice,RsiMethod,speed,FastMaPeriod,FastMa_Mode,SlowMaPeriod,SlowMa_Mode,SmoothLength,SmoothPhase,SmoothDouble,levelOs,levelOb,0,y);
            fastma[i]     = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",swingCount,RsiPrice,RsiMethod,speed,FastMaPeriod,FastMa_Mode,SlowMaPeriod,SlowMa_Mode,SmoothLength,SmoothPhase,SmoothDouble,levelOs,levelOb,1,y);
            slowma[i]     = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",swingCount,RsiPrice,RsiMethod,speed,FastMaPeriod,FastMa_Mode,SlowMaPeriod,SlowMa_Mode,SmoothLength,SmoothPhase,SmoothDouble,levelOs,levelOb,2,y);
            swingBuffer[i]= iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",swingCount,RsiPrice,RsiMethod,speed,FastMaPeriod,FastMa_Mode,SlowMaPeriod,SlowMa_Mode,SmoothLength,SmoothPhase,SmoothDouble,levelOs,levelOb,3,y);
            trend[i]      = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",swingCount,RsiPrice,RsiMethod,speed,FastMaPeriod,FastMa_Mode,SlowMaPeriod,SlowMa_Mode,SmoothLength,SmoothPhase,SmoothDouble,levelOs,levelOb,4,y);
            
            manageArrow(i);
            
            //
            //
            //
            //
            //
            
            if (!Interpolate || y==iBarShift(NULL,timeFrame,Time[i-1])) continue;

            //
            //
            //
            //
            //

            datetime time = iTime(NULL,timeFrame,y);
            for(x = 1; i+x < Bars && Time[i+x] >= time; x++) continue;	
            for(s = 1; s < x; s++)
            {
  	            rsiBuffer[i+s]   = rsiBuffer[i]   + (rsiBuffer[i+x]   - rsiBuffer[i])   * s/x;
  	            fastma[i+s]      = fastma[i]      + (fastma[i+x]      - fastma[i])      * s/x;
  	            slowma[i+s]      = slowma[i]      + (slowma[i+x]      - slowma[i])      * s/x;
  	            swingBuffer[i+s] = swingBuffer[i] + (swingBuffer[i+x] - swingBuffer[i]) * s/x;
  	  
           }  	            
   }
   
   manageAlerts();
      
   return(0);
}

//+-------------------------------------------------------------------
//|                                                                  
//+-------------------------------------------------------------------
//
//
//
//
//

string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int    iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};

//
//
//
//
//

int stringToTimeFrame(string tfs)
{
   tfs = stringUpperCase(tfs);
   for (int i=ArraySize(iTfTable)-1; i>=0; i--)
         if (tfs==sTfTable[i] || tfs==""+iTfTable[i]) return(MathMax(iTfTable[i],Period()));
                                                      return(Period());
}
string timeFrameToString(int tf)
{
   for (int i=ArraySize(iTfTable)-1; i>=0; i--) 
         if (tf==iTfTable[i]) return(sTfTable[i]);
                              return("");
}

//
//
//
//
//

string stringUpperCase(string str)
{
   string   s = str;

   for (int length=StringLen(str)-1; length>=0; length--)
   {
      int tchar = StringGetChar(s, length);
         if((tchar > 96 && tchar < 123) || (tchar > 223 && tchar < 256))
                     s = StringSetChar(s, length, tchar - 32);
         else if(tchar > -33 && tchar < 0)
                     s = StringSetChar(s, length, tchar + 224);
   }
   return(s);
   
}

//
//
//
//
//
//+---------------------------------------------------------------------------------------+
//
//
//
//

void manageAlerts()
{
   if (!calculateValue && alertsOn)
   {
      if (alertsOnCurrent)
           int whichBar = 0;
      else     whichBar = 1; whichBar = iBarShift(NULL,0,iTime(NULL,timeFrame,whichBar));
      if (trend[whichBar] != trend[whichBar+1])
      {
         if (trend[whichBar] ==  1) doAlert(whichBar,"up");
         if (trend[whichBar] == -1) doAlert(whichBar,"down");
      }
   }
}

//
//
//
//
//

void doAlert(int forBar, string doWhat)
{
   static string   previousAlert="nothing";
   static datetime previousTime;
   string message;
   
   if (previousAlert != doWhat || previousTime != Time[forBar]) {
       previousAlert  = doWhat;
       previousTime   = Time[forBar];

       //
       //
       //
       //
       //

       message =  StringConcatenate(Symbol()," ",timeFrameToString(timeFrame)," at ",TimeToStr(TimeLocal(),TIME_SECONDS)," alb of "+getRsiName(RsiMethod)+" trend changed to ",doWhat);
          if (alertsMessage) Alert(message);
          if (alertsEmail)   SendMail(StringConcatenate(Symbol()," alb of "+getRsiName(RsiMethod)+" "),message);
          if (alertsSound)   PlaySound("alert2.wav");
   }
}

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

void manageArrow(int i)
{
   if (ShowArrows)
   {
      deleteArrow(Time[i]);
      if (trend[i]!=trend[i+1])
      {
         if (trend[i] == 1) drawArrow(i,arrowsUpColor,225,false);
         if (trend[i] ==-1) drawArrow(i,arrowsDnColor,226,true);
      }
   }
}               

//
//
//
//
//

void drawArrow(int i,color theColor,int theCode,bool up)
{
   string name = arrowsIdentifier+":"+Time[i];
   double gap  = 3.0*iATR(NULL,0,20,i)/4.0;   
   
      //
      //
      //
      //
      //
      
      ObjectCreate(name,OBJ_ARROW,0,Time[i],0);
         ObjectSet(name,OBJPROP_ARROWCODE,theCode);
         ObjectSet(name,OBJPROP_COLOR,theColor);
         if (up)
               ObjectSet(name,OBJPROP_PRICE1,High[i]+ gap);
         else  ObjectSet(name,OBJPROP_PRICE1,Low[i] - gap);
}

//
//
//
//
//

void deleteArrows()
{
   string lookFor       = arrowsIdentifier+":";
   int    lookForLength = StringLen(lookFor);
   for (int i=ObjectsTotal()-1; i>=0; i--)
   {
      string objectName = ObjectName(i);
         if (StringSubstr(objectName,0,lookForLength) == lookFor) ObjectDelete(objectName);
   }
}
void deleteArrow(datetime time)
{
   string lookFor = arrowsIdentifier+":"+time; ObjectDelete(lookFor);
}

//+------------------------------------------------------------------
//|                                                                  
//+------------------------------------------------------------------
//
//
//
//
//

double getPrice(int type, int i)
{
   switch (type)
   {
      case 7:     return((Open[i]+Close[i])/2.0);
      case 8:     return((Open[i]+High[i]+Low[i]+Close[i])/4.0);
      default :   return(iMA(NULL,0,1,0,MODE_SMA,type,i));
   }      
}

//+------------------------------------------------------------------
//|                                                                  
//+------------------------------------------------------------------
//
//
//
//
//
//

string rsiMethodNames[] = {"rsi","rsx","Ehlers rsi"};
string getRsiName(int& method)
{
   int max = ArraySize(rsiMethodNames)-1;
      method=MathMax(MathMin(method,max),0); return(rsiMethodNames[method]);
}

//
//
//
//
//

double workRsi[][13];
#define _price  0
#define _change 1
#define _changa 2

double iRsi(double price, double period, int i, int instanceNo=0, int rsiMode=0)
{
   if (ArrayRange(workRsi,0)!=Bars) ArrayResize(workRsi,Bars);
      int z = instanceNo*3; 
      int r = Bars-i-1;
   
   //
   //
   //
   //
   //
   
   workRsi[r][z+_price] = price;
   switch (rsiMode)
   {
      case 0:
         double alpha = 1.0/period; 
         if (r<period)
            {
               int k; double sum = 0; for (k=0; k<period && (i-k-1)>=0; k++) sum += MathAbs(workRsi[r-k][z+_price]-workRsi[r-k-1][z+_price]);
                  workRsi[r][z+_change] = (workRsi[r][z+_price]-workRsi[0][z+_price])/MathMax(k,1);
                  workRsi[r][z+_changa] =                                         sum/MathMax(k,1);
            }
         else
            {
               double change = workRsi[r][z+_price]-workRsi[r-1][z+_price];
                               workRsi[r][z+_change] = workRsi[r-1][z+_change] + alpha*(        change  - workRsi[r-1][z+_change]);
                               workRsi[r][z+_changa] = workRsi[r-1][z+_changa] + alpha*(MathAbs(change) - workRsi[r-1][z+_changa]);
            }
         if (workRsi[r][z+_changa] != 0)
               return(50.0*(workRsi[r][z+_change]/workRsi[r][z+_changa]+1));
         else  return(50.0);
         
      //
      //
      //
      //
      //
      
    
      case 1 :     
         double Kg = (3.0)/(2.0+period), Hg = 1.0-Kg;
            if (r<period) { for (k=1; k<13; k++) workRsi[r][k+z] = 0; return(50); }  

            //
            //
            //
            //
            //
      
            double mom = workRsi[r][_price+z]-workRsi[r-1][_price+z];
            double moa = MathAbs(mom);
            for (k=0; k<3; k++)
            {
               int kk = k*2;
               workRsi[r][z+kk+1] = Kg*mom                + Hg*workRsi[r-1][z+kk+1];
               workRsi[r][z+kk+2] = Kg*workRsi[r][z+kk+1] + Hg*workRsi[r-1][z+kk+2]; mom = 1.5*workRsi[r][z+kk+1] - 0.5 * workRsi[r][z+kk+2];
               workRsi[r][z+kk+7] = Kg*moa                + Hg*workRsi[r-1][z+kk+7];
               workRsi[r][z+kk+8] = Kg*workRsi[r][z+kk+7] + Hg*workRsi[r-1][z+kk+8]; moa = 1.5*workRsi[r][z+kk+7] - 0.5 * workRsi[r][z+kk+8];
            }
            if (moa != 0)
                 return(MathMax(MathMin((mom/moa+1.0)*50.0,100.00),0.00)); 
            else return(50);
            
      //
      //
      //
      //
      //
      
      case 2 :
      
         double changeu = 0;
         double changed = 0;
         for (k=0; k<period; k++)
            {
               double diff = workRsi[r-k][_price+z]-workRsi[r-k-1][_price+z];
                  if (diff > 0)
                        changeu += diff;
                  else  changed -= diff;
            }
         if ((changeu+changed)!=0)
               return(50.0*((changeu-changed)/(changeu+changed)+1.0));
         else  return(50.0);
   } 
}

//+-----------------------------------------------------------------------------------------
//|                                                                 
//+-----------------------------------------------------------------------------------------
//
//
//
//
//

double wrk[][40];

#define bsmax  5
#define bsmin  6
#define volty  7
#define vsum   8
#define avolty 9

//
//
//
//
//

double iDSmooth(double price, double length, double phase, bool isDouble, int i, int s=0)
{
   if (isDouble)
         return (iSmooth(iSmooth(price,MathSqrt(length),phase,i,s),MathSqrt(length),phase,i,s+10));
   else  return (iSmooth(price,length,phase,i,s));
}

//
//
//
//
//

double iSmooth(double price, double length, double phase, int i, int s=0)
{
   if (length <=1) return(price);
   if (ArrayRange(wrk,0) != Bars) ArrayResize(wrk,Bars);
   
   int r = Bars-i-1; 
      if (r==0) { for(int k=0; k<7; k++) wrk[r][k+s]=price; for(; k<10; k++) wrk[r][k+s]=0; return(price); }

   //
   //
   //
   //
   //
   
      double len1   = MathMax(MathLog(MathSqrt(0.5*(length-1)))/MathLog(2.0)+2.0,0);
      double pow1   = MathMax(len1-2.0,0.5);
      double del1   = price - wrk[r-1][bsmax+s];
      double del2   = price - wrk[r-1][bsmin+s];
      double div    = 1.0/(10.0+10.0*(MathMin(MathMax(length-10,0),100))/100);
      int    forBar = MathMin(r,10);
	
         wrk[r][volty+s] = 0;
               if(MathAbs(del1) > MathAbs(del2)) wrk[r][volty+s] = MathAbs(del1); 
               if(MathAbs(del1) < MathAbs(del2)) wrk[r][volty+s] = MathAbs(del2); 
         wrk[r][vsum+s] =	wrk[r-1][vsum+s] + (wrk[r][volty+s]-wrk[r-forBar][volty+s])*div;
         
         //
         //
         //
         //
         //
   
         wrk[r][avolty+s] = wrk[r-1][avolty+s]+(2.0/(MathMax(4.0*length,30)+1.0))*(wrk[r][vsum+s]-wrk[r-1][avolty+s]);
            if (wrk[r][avolty+s] > 0)
               double dVolty = wrk[r][volty+s]/wrk[r][avolty+s]; else dVolty = 0;   
	               if (dVolty > MathPow(len1,1.0/pow1)) dVolty = MathPow(len1,1.0/pow1);
                  if (dVolty < 1)                      dVolty = 1.0;

      //
      //
      //
      //
      //
	        
   	double pow2 = MathPow(dVolty, pow1);
      double len2 = MathSqrt(0.5*(length-1))*len1;
      double Kv   = MathPow(len2/(len2+1), MathSqrt(pow2));

         if (del1 > 0) wrk[r][bsmax+s] = price; else wrk[r][bsmax+s] = price - Kv*del1;
         if (del2 < 0) wrk[r][bsmin+s] = price; else wrk[r][bsmin+s] = price - Kv*del2;
	
   //
   //
   //
   //
   //
      
      double R     = MathMax(MathMin(phase,100),-100)/100.0 + 1.5;
      double beta  = 0.45*(length-1)/(0.45*(length-1)+2);
      double alpha = MathPow(beta,pow2);

         wrk[r][0+s] = price + alpha*(wrk[r-1][0+s]-price);
         wrk[r][1+s] = (price - wrk[r][0+s])*(1-beta) + beta*wrk[r-1][1+s];
         wrk[r][2+s] = (wrk[r][0+s] + R*wrk[r][1+s]);
         wrk[r][3+s] = (wrk[r][2+s] - wrk[r-1][4+s])*MathPow((1-alpha),2) + MathPow(alpha,2)*wrk[r-1][3+s];
         wrk[r][4+s] = (wrk[r-1][4+s] + wrk[r][3+s]); 

   //
   //
   //
   //
   //

   return(wrk[r][4+s]);
}