//+------------------------------------------------------------------+
//|                                                    MA ribbon.mq4 |
//|                                               mladenfx@gmail.com |
//|                                                                  |
//| original idea by Jose Silva                                      |
//+------------------------------------------------------------------+
#property copyright "mladen"
#property link      "mladenfx@gmail.com"

#property indicator_chart_window
#property indicator_buffers 4
#property indicator_color1  clrCrimson  //C'97,48,48'  /////C'217,240,242'   //C'215,255,225'
#property indicator_color2  clrDarkGray  //C'36,62,62'             ///C'240,235,183'    ///OldLace   //Gainsboro
#property indicator_color3  clrTeal
#property indicator_color4  clrChocolate

//
//
//

extern ENUM_TIMEFRAMES    TimeFrame = PERIOD_CURRENT; // Time frame
extern int                MA1Period = 9;
extern ENUM_MA_METHOD     MA1Method = MODE_EMA;
extern ENUM_APPLIED_PRICE MA1Price  = PRICE_WEIGHTED;
extern int                MA1Shift  = 1;
extern int                MA2Period = 1;
extern ENUM_MA_METHOD     MA2Method = MODE_EMA;
extern ENUM_APPLIED_PRICE MA2Price  = PRICE_WEIGHTED;
extern int                MA2Shift  = 0;
extern int                FillWidth = 9;
extern int                LineWidth = 9;
extern bool               Interpolate = true;           // Interpolate in mtf mode


double buffer1[],buffer2[],buffer3[],buffer4[],count[];
string indicatorFileName;
#define _mtfCall(_buff,_ind) iCustom(NULL,TimeFrame,indicatorFileName,0,MA1Period,MA1Method,MA1Price,MA1Shift,MA2Period,MA2Method,MA2Price,MA2Shift,_buff,_ind)

//------------------------------------------------------------------
//
//------------------------------------------------------------------

int init()
{
   IndicatorBuffers(5);
   SetIndexBuffer(0,buffer3); SetIndexStyle(0,DRAW_HISTOGRAM,EMPTY,FillWidth);
   SetIndexBuffer(1,buffer4); SetIndexStyle(1,DRAW_HISTOGRAM,EMPTY,FillWidth);
   SetIndexBuffer(2,buffer1); SetIndexStyle(2,DRAW_LINE,EMPTY,LineWidth); 
   SetIndexBuffer(3,buffer2); SetIndexStyle(3,DRAW_LINE,EMPTY,LineWidth);
   SetIndexBuffer(4,count);
      
      //
      //
      //
      //
      //
      
      MA1Method         = MathMin(MathMax(MA1Method,0),4);
      MA2Method         = MathMin(MathMax(MA2Method,0),4);
      indicatorFileName = WindowExpertName();
      TimeFrame         = MathMax(TimeFrame,_Period);
      SetIndexShift(0,MA1Shift * TimeFrame/_Period);  
      SetIndexShift(1,MA2Shift * TimeFrame/_Period); 
      SetIndexShift(2,MA1Shift * TimeFrame/_Period);  
      SetIndexShift(3,MA2Shift * TimeFrame/_Period); 
      
      IndicatorShortName(timeFrameToString(TimeFrame)+" MA Ribbon filled"); 
return(0);
}
int deinit()
{
   return(0);
}

//------------------------------------------------------------------
//
//------------------------------------------------------------------
//
//
//
//
//

int start()
{
  int limit,i,counted_bars=IndicatorCounted();
      if(counted_bars<0) return(-1);
      if(counted_bars>0) counted_bars--;
           limit=MathMin(Bars-counted_bars,Bars-1); count[0] = limit;
           if (MA1Shift < 0) limit = fmax(limit,-MA1Shift);
           if (MA2Shift < 0) limit = fmax(limit,-MA2Shift);

   //
   //
   //
   //
   //

   if (TimeFrame == Period())
   {
     for(i=limit; i>=0; i--)
     {
        if (MA1Method<4) 
              buffer1[i] = iMA(NULL,0,MA1Period,MA1Shift,MA1Method,MA1Price,i);
        else  buffer1[i] = iLsma(iMA(NULL,0,1,MA1Shift,MODE_SMA,MA1Price,i),MA1Period,i,0);
        if (MA2Method<4) 
              buffer2[i] = iMA(NULL,0,MA2Period,MA2Shift,MA2Method,MA2Price,i);
        else  buffer2[i] = iLsma(iMA(NULL,0,1,MA2Shift,MODE_SMA,MA2Price,i),MA2Period,i,1);
        buffer3[i] = buffer1[i];
        buffer4[i] = buffer2[i];
     }
   return(0);
   }
   
   //
   //
   //
   //
   //
   
   limit = (int)MathMax(limit,MathMin(Bars-1,_mtfCall(4,0)*TimeFrame/_Period));
   for (i=limit;i>=0;i--)
   {
      int y = iBarShift(NULL,TimeFrame,Time[i]);
         buffer1[i] = _mtfCall(2,y);
         buffer2[i] = _mtfCall(3,y);
         buffer3[i] = buffer1[i];
         buffer4[i] = buffer2[i];

         //
         //
         //
         //
         //
      
            if (!Interpolate || y==iBarShift(NULL,TimeFrame,Time[i-1])) continue;

         //
         //
         //
         //
         //

         int n,k; datetime time = iTime(NULL,TimeFrame,y);
            for(n = 1; i+n < Bars && Time[i+n] >= time; n++) continue;	
            for(k = 1; k < n && (i+n)<Bars && (i+k)<Bars; k++)
            {
               buffer1[i+k] = buffer1[i] + (buffer1[i+n]-buffer1[i])*k/n;
               buffer2[i+k] = buffer2[i] + (buffer2[i+n]-buffer2[i])*k/n;
               buffer3[i+k] = buffer1[i+k];
               buffer4[i+k] = buffer2[i+k];
            }
   }
   return(0);
}


//------------------------------------------------------------------
//
//------------------------------------------------------------------
//
//
//
//
//

double workLsma[][2];
double iLsma(double price, double period, int r, int instanceNo=0)
{
   if (ArrayRange(workLsma,0)!= Bars) ArrayResize(workLsma,Bars); r = Bars-r-1;

   //
   //
   //
   //
   //
   
      period = MathMax(period,1);
      workLsma[r][instanceNo] = price;
         double lwmw = period; double lwma = lwmw*price;
         double sma  = price;
         for(int k=1; k<period && (r-k)>=0; k++)
         {
            double weight = period-k;
                   lwmw  += weight;
                   lwma  += weight*workLsma[r-k][instanceNo];  
                   sma   +=        workLsma[r-k][instanceNo];
         }             
   
   return(3.0*lwma/lwmw-2.0*sma/period);
}

//+-------------------------------------------------------------------
//|                                                                  
//+-------------------------------------------------------------------

string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int    iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};

string timeFrameToString(int tf)
{
   for (int i=ArraySize(iTfTable)-1; i>=0; i--) 
         if (tf==iTfTable[i]) return(sTfTable[i]);
                              return("");
}