//+------------------------------------------------------------------+
//|                                              NonLagZigZag_v2.mq4 |
//|                                Copyright © 2006, TrendLaboratory |
//|            http://finance.groups.yahoo.com/group/TrendLaboratory |
//|                                   E-mail: igorad2003@yahoo.co.uk |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2006, TrendLaboratory"
#property link      "http://finance.groups.yahoo.com/group/TrendLaboratory"


#property indicator_chart_window
#property indicator_buffers 1
#property indicator_color1 PaleVioletRed
#property indicator_width1 2

//---- input parameters
extern int     Price          =    0;  //Apply to Price(0-Close;1-Open;2-High;3-Low;4-Median price;5-Typical price;6-Weighted Close) 
extern int     Length         =   100;  //Period of NonLagMA
extern double  PctFilter      =    2;  //Dynamic filter in decimals

double ZZBuffer[];
double MABuffer[];
double trend[];
double Del[];
double AvgDel[];
double SumDel[];
double SumPow[];
double pipMultiplier = 1;

int    ilow, ihigh, nlow, nhigh, prevnhigh,prevnlow, BarsBack;  
double alfa[];
datetime lotime,hitime;
int    Phase, Len, Cycle=4, Back=0;
double Coeff, beta, t, Sum, Weight, g;
double pi = 3.1415926535;    
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
  int init()
  {
   IndicatorBuffers(7);
   SetIndexStyle(0,DRAW_SECTION);
   SetIndexBuffer(0,ZZBuffer);
   SetIndexBuffer(1,MABuffer);
   SetIndexBuffer(2,trend);
   SetIndexBuffer(3,Del);
   SetIndexBuffer(4,AvgDel); 
   SetIndexBuffer(5,SumDel);
   SetIndexBuffer(6,SumPow);
   string short_name;
//---- indicator line
   
   IndicatorDigits(MarketInfo(Symbol(),MODE_DIGITS));
//---- name for DataWindow and indicator subwindow label
   short_name="NonLagZigZag("+Length+")";
   IndicatorShortName(short_name);
   SetIndexLabel(0,"NonLagZigZag");
//----
   SetIndexEmptyValue(0,0.0);   
   SetIndexDrawBegin(0,Length*Cycle+Length);
//----
   
   Coeff =  3*pi;
   Phase = Length-1;
   Len = Length*Cycle + Phase;  
   ArrayResize(alfa,Len);
   Weight=0;    
      
      for (int i=0;i<Len;i++)
      {
      if (i<=Phase-1) t = 1.0*i/(Phase-1);
      else t = 1.0 + (i-Phase+1)*(2.0*Cycle-1.0)/(Cycle*Length-1.0); 
      beta = MathCos(pi*t);
      g = 1.0/(Coeff*t+1);   
      if (t <= 0.5 ) g = 1;
      alfa[i] = g * beta;
      Weight += alfa[i];
      }
 
   return(0);
  }

//+------------------------------------------------------------------+
//| NonLagZigZag_v2                                                  |
//+------------------------------------------------------------------+
int start()
{
   int    i,shift, counted_bars=IndicatorCounted(),limit;
 
   if (Weight <=0)  return(0);
   if (Digits==3 || Digits==5) 
         pipMultiplier = 10;
   else  pipMultiplier = 1;      
        
   if ( counted_bars > 0 )  limit=Bars-counted_bars;
   if ( counted_bars < 0 )  return(0);
   if ( counted_bars ==0 )  limit=Bars-1; 
   if ( counted_bars < 1 ) 
   {
   for(i=0;i<Bars-1;i++) 
   ZZBuffer[i]=0;
   for(i=1;i<Len;i++) 
   MABuffer[Bars-i]=iMA(NULL,0,1,0,MODE_SMA,Price,Bars-i);    
   }
   
   for(shift=limit; shift>=0; shift--) 
   {	
      for (i=0, MABuffer[shift]=0;i<Len;i++) MABuffer[shift] += alfa[i]*iMA(NULL,0,1,0,1,Price,i+shift);
	                                          MABuffer[shift] /= Weight;
   
      Del[shift]    = MathAbs(MABuffer[shift]-MABuffer[shift+1]);
      SumDel[shift] = SumDel[shift+1]-Del[shift+Length]+Del[shift];
         if ((Bars-shift) <= Length)
                  for (i=0, SumDel[shift]=0; i < Length; i++) SumDel[shift] += Del[shift+i];
      AvgDel[shift] = SumDel[shift]/Length;
      SumPow[shift] = SumPow[shift+1]-MathPow(Del[shift+Length]-AvgDel[shift+Length],2)+MathPow(Del[shift]-AvgDel[shift],2);
         if ((Bars-shift) <= Length)
                  for (i=0, SumPow[shift]=0; i < Length; i++) SumPow[shift] += MathPow(Del[shift+i]-AvgDel[shift+i],2);
      double StdDev = MathSqrt(SumPow[shift]/Length); 
      double Filter = PctFilter * StdDev;       

      
      if (Filter < Point*pipMultiplier) Filter = Point*pipMultiplier;
   
   if( MathAbs(MABuffer[shift]-MABuffer[shift+1]) < Filter ) MABuffer[shift]=MABuffer[shift+1];
   
   trend[shift]=trend[shift+1];
   if (MABuffer[shift]-MABuffer[shift+1] > Filter) trend[shift]= 1;   
   if (MABuffer[shift+1]-MABuffer[shift] > Filter) trend[shift]=-1;
   
      if(trend[shift]>0)
      {
         if( trend[shift]!=trend[shift+1]) 
         {
            ilow = LowestBar(iBarShift(NULL,0,hitime,FALSE)-shift,shift);
            lotime = Time[ilow];
            ZZBuffer[ilow] = Low[ilow];
         }
         else
         if (shift==0) 
         {
            int hilen = iBarShift(NULL,0,lotime,FALSE);
            nhigh = HighestBar(hilen,0);
            ZZBuffer[nhigh]=High[nhigh];
               if (nhigh== 0) for (i=hilen-1;i>=1;i--) ZZBuffer[i]=0; 
               if (nhigh > 0) for (i=nhigh-1;i>=0;i--) ZZBuffer[i]=0; 
         }
      }
      
      if (trend[shift]<0)
      { 
         if( trend[shift]!=trend[shift+1]) 
         {
         ihigh = HighestBar(iBarShift(NULL,0,lotime,FALSE)-shift,shift);
         hitime=Time[ihigh];
         ZZBuffer[ihigh] = High[ihigh];
         }
         else
         if (shift==0) 
         {
         int lolen = iBarShift(NULL,0,hitime,FALSE);
         nlow = LowestBar(lolen,0);
         ZZBuffer[nlow] = Low[nlow]; 
         if (nlow==0) for (i=lolen-1;i>=1;i--) ZZBuffer[i]=0; 
         if (nlow >0) for (i=nlow-1;i>=0;i--) ZZBuffer[i]=0; 
         }
      }
   }
   return(0);	
}

int LowestBar(int len,int k)
{
   double min = 10000000;   
   int lobar;
   
   for (int i=k+len-1;i>=k;i--)
   if(Low[i] < min) {min = Low[i]; lobar = i;}
   if(len<=0) lobar=k;
   return(lobar);
} 

int HighestBar(int len,int k)
{
   double max = -10000000;   
   int hibar;
   
   for (int i=k+len-1;i>=k;i--)
   if(High[i] > max) {max = High[i]; hibar = i;}
   
   if(len<=0) hibar=k;
   return(hibar);
}