//+------------------------------------------------------------------+
//|                                                  Ultra trend.mq4 |
//|                                                           mladen |
//+------------------------------------------------------------------+
#property copyright "copyleft mladen"
#property link      "mladenfx@gmail.com"

#property indicator_separate_window
#property indicator_buffers    2
#property indicator_color1     clrLimeGreen
#property indicator_color2     clrRed
#property indicator_level1     19
#property indicator_levelstyle STYLE_DOT
#property indicator_levelcolor clrSilver

//
//
//
//
//

extern string TimeFrame       = "Current time frame";
extern int    BarsToCount     = 1000;
extern int    Length          = 3;
extern int    Progression     = 8;
extern int    Sensitivity     = 30;
extern int    Smooth          = 5;
extern int    SmoothPhase     = 100;
extern bool   Interpolate     = true;
input bool    alertsOn        = true;               // Alerts on/off?
input bool    alertsOnCurrent = false;              // Alerts on current (still opened) bar on/off?
input bool    alertsMessage   = true;               // Alerts message on/off?
input bool    alertsSound     = false;              // Alert sound on/off?
input bool    alertsNotify    = false;              // Alerts push notification on/off?
input bool    alertsEmail     = false;              // Alerts email on/off?

//
//
//
//
//

double buffer1[];
double buffer2[];
double trend[];
bool   Calculating;
bool   ReturningBars;
string indicatorFileName;
int    timeFrame;

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int init()
{
   IndicatorBuffers(3);
   SetIndexBuffer(0,buffer1);
      Calculating       = (TimeFrame=="calculate");   if (Calculating) return(0);
      ReturningBars     = (TimeFrame=="returnBars");  if (ReturningBars) return(0);
      indicatorFileName = WindowExpertName();

      //
      //
      //
      //
      //
      
      SetIndexBuffer(1,buffer2);
      SetIndexBuffer(2,trend);
     
      timeFrame = stringToTimeFrame(TimeFrame);
      IndicatorShortName("ultra trend "+timeFrameToString(timeFrame)+" ("+Length+","+Progression+","+Sensitivity+")");
   return(0);
}

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int start()
{
   int endLength    = Length + Progression * Sensitivity;            
   int counted_bars = IndicatorCounted();
   int i,limit;
   
   if(counted_bars < 0) return(-1);
   if(counted_bars > 0) counted_bars--;
            limit = MathMin(Bars-counted_bars,Bars-1);
            if (ReturningBars)  { buffer1[0] = limit; return(0); }

   //
   //
   //
   //
   //
   
      if (Calculating)
      {
         for (i=limit; i>=0; i--) buffer1[i] = iSmooth(iMA(NULL,0,1,0,MODE_SMA,PRICE_CLOSE,i),Length,Progression,i,0);
         return(0);
      }         

   //
   //
   //
   //
   //

   if (BarsToCount==0)
         limit = MathMin(Bars-counted_bars,Bars-1);
   else  limit = MathMin(MathMax(BarsToCount-counted_bars,1),BarsToCount-1);
   if (timeFrame > Period()) limit = MathMax(limit,MathMin(Bars,iCustom(NULL,timeFrame,indicatorFileName,"returnBars",0,0)*timeFrame/Period()));

   //
   //
   //
   //
   //
   
   for (i=limit; i>=0; i--)
   {
      int y = iBarShift(NULL,timeFrame,Time[i]);
         double valueUp=0;
         double valueDn=0;
         
            for (int k = Length; k <= endLength; k += Progression)
               if (iCustom(NULL,timeFrame,indicatorFileName,"calculate",BarsToCount,k,0,0,y) > iCustom(NULL,timeFrame,indicatorFileName,"calculate",BarsToCount,k,0,0,y+1))
                    valueUp++;
               else valueDn++;
               
         buffer1[i] = iSmooth(valueUp,Smooth,SmoothPhase,i, 0);
         buffer2[i] = iSmooth(valueDn,Smooth,SmoothPhase,i,10);
         trend[i] = trend[i+1];
            if (buffer1[i]>buffer2[i]) trend[i] =  1;
            if (buffer2[i]>buffer1[i]) trend[i] = -1;

         //
         //
         //
         //
         //
         
         if (timeFrame <= Period() || y==iBarShift(NULL,timeFrame,Time[i-1])) continue;
         if (!Interpolate) continue;

         //
         //
         //
         //
         //

         datetime time = iTime(NULL,timeFrame,y);
            for(int n = 1; i+n < Bars && Time[i+n] >= time; n++) continue;	
            double factor = 1.0 / n;
            for(k = 1; k < n; k++)
            {
  	             buffer1[i+k] = k*factor*buffer1[i+n] + (1.0-k*factor)*buffer1[i];
  	             buffer2[i+k] = k*factor*buffer2[i+n] + (1.0-k*factor)*buffer2[i];
            }
   }
   manageAlerts();
   return(0);
}

//+------------------------------------------------------------------
//|                                                                 
//+------------------------------------------------------------------
//
//
//
//
//

double wrk[][20];
double init[2];
#define bsmax  5
#define bsmin  6
#define volty  7
#define vsum   8
#define avolty 9

//
//
//
//
//

double iSmooth(double price, double length, double phase, int i, int s=0)
{
   if (ArrayRange(wrk,0) != Bars) ArrayResize(wrk,Bars);
   if (length<=1) return(price);
   
   int r = Bars-i-1; 
      if (init[s/10]!=999) { for(int k=0; k<7; k++) wrk[r][k+s]=price; for(; k<10; k++) wrk[r][k+s]=0; init[s/10]=999; return(price); }

   //
   //
   //
   //
   //
   
      double len1   = MathMax(MathLog(MathSqrt(0.5*(length-1)))/MathLog(2.0)+2.0,0);
      double pow1   = MathMax(len1-2.0,0.5);
      double del1   = price - wrk[r-1][bsmax+s];
      double del2   = price - wrk[r-1][bsmin+s];
      int    forBar = MathMin(r,10);
	
         wrk[r][volty+s] = 0;
               if(MathAbs(del1) > MathAbs(del2)) wrk[r][volty+s] = MathAbs(del1); 
               if(MathAbs(del1) < MathAbs(del2)) wrk[r][volty+s] = MathAbs(del2); 
         wrk[r][vsum+s] =	wrk[r-1][vsum+s] + (wrk[r][volty+s]-wrk[r-forBar][volty+s])*0.1;
         
         //
         //
         //
         //
         //
   
         wrk[r][avolty+s] = wrk[r-1][avolty+s]+(2.0/(MathMax(4.0*length,30)+1.0))*(wrk[r][vsum+s]-wrk[r-1][avolty+s]);
            if (wrk[r][avolty+s] > 0)
               double dVolty = wrk[r][volty+s]/wrk[r][avolty+s]; else dVolty = 0;   
	               if (dVolty > MathPow(len1,1.0/pow1)) dVolty = MathPow(len1,1.0/pow1);
                  if (dVolty < 1)                      dVolty = 1.0;

      //
      //
      //
      //
      //
	        
   	double pow2 = MathPow(dVolty, pow1);
      double len2 = MathSqrt(0.5*(length-1))*len1;
      double Kv   = MathPow(len2/(len2+1), MathSqrt(pow2));

         if (del1 > 0) wrk[r][bsmax+s] = price; else wrk[r][bsmax+s] = price - Kv*del1;
         if (del2 < 0) wrk[r][bsmin+s] = price; else wrk[r][bsmin+s] = price - Kv*del2;
	
   //
   //
   //
   //
   //
      
      double R     = MathMax(MathMin(phase,100),-100)/100.0 + 1.5;
      double beta  = 0.45*(length-1)/(0.45*(length-1)+2);
      double alpha = MathPow(beta,pow2);

         wrk[r][0+s] = price + alpha*(wrk[r-1][0+s]-price);
         wrk[r][1+s] = (price - wrk[r][0+s])*(1-beta) + beta*wrk[r-1][1+s];
         wrk[r][2+s] = (wrk[r][0+s] + R*wrk[r][1+s]);
         wrk[r][3+s] = (wrk[r][2+s] - wrk[r-1][4+s])*MathPow((1-alpha),2) + MathPow(alpha,2)*wrk[r-1][3+s];
         wrk[r][4+s] = (wrk[r-1][4+s] + wrk[r][3+s]); 

   //
   //
   //
   //
   //

   return(wrk[r][4+s]);
}

//+-------------------------------------------------------------------
//|                                                                  
//+-------------------------------------------------------------------
//
//
//
//
//

void manageAlerts()
{
   if (alertsOn)
   {
      if (alertsOnCurrent)
           int whichBar = 0;
      else     whichBar = 1;  whichBar = iBarShift(NULL,0,iTime(NULL,timeFrame,whichBar));
      if (trend[whichBar] != trend[whichBar+1])
      {
         if (trend[whichBar] ==  1) doAlert(whichBar,"up");
         if (trend[whichBar] == -1) doAlert(whichBar,"down");
      }
   }
}

//
//
//
//
//

void doAlert(int forBar, string doWhat)
{
   static string   previousAlert="nothing";
   static datetime previousTime;
   string message;
   
   if (previousAlert != doWhat || previousTime != Time[forBar]) {
       previousAlert  = doWhat;
       previousTime   = Time[forBar];

       //
       //
       //
       //
       //
       
        message = timeFrameToString(_Period)+" "+_Symbol+" at "+TimeToStr(TimeLocal(),TIME_SECONDS)+" Ultra trend "+doWhat;
             if (alertsMessage) Alert(message);
             if (alertsNotify)  SendNotification(message);
             if (alertsEmail)   SendMail(_Symbol+" Ultra trend ",message);
             if (alertsSound)   PlaySound("alert2.wav");
      }
}
      
 
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int    iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};

//
//
//
//
//

int stringToTimeFrame(string tfs)
{
   tfs = StringUpperCase(tfs);
   for (int i=ArraySize(iTfTable)-1; i>=0; i--)
         if (tfs==sTfTable[i] || tfs==""+iTfTable[i]) return(MathMax(iTfTable[i],Period()));
                                                      return(Period());
}
string timeFrameToString(int tf)
{
   for (int i=ArraySize(iTfTable)-1; i>=0; i--) 
         if (tf==iTfTable[i]) return(sTfTable[i]);
                              return("");
}

//
//
//
//
//

string StringUpperCase(string str)
{
   string   s = str;

   for (int length=StringLen(str)-1; length>=0; length--)
   {
      int tchar = StringGetChar(s, length);
         if((tchar > 96 && tchar < 123) || (tchar > 223 && tchar < 256))
                     s = StringSetChar(s, length, tchar - 32);
         else if(tchar > -33 && tchar < 0)
                     s = StringSetChar(s, length, tchar + 224);
   }
   return(s);
}