//+------------------------------------------------------------------+
//|                                    Spearman Rank Correlation.mq4 |
//+------------------------------------------------------------------+
#property copyright "www.forex-tsd.com"
#property link      "www.forex-tsd.com"

#property indicator_separate_window
#property indicator_buffers  6
#property indicator_color1   Goldenrod
#property indicator_color2   LimeGreen
#property indicator_color3   LimeGreen
#property indicator_color4   Red
#property indicator_color5   Red
#property indicator_color6   DimGray
#property indicator_style3   STYLE_DOT
#property indicator_style4   STYLE_DOT
#property indicator_style6   STYLE_DOT
#property indicator_width1   2
#property indicator_minimum  -1.05
#property indicator_maximum  1.05

//
//
//
//
//

#import "dynamicZone.dll"
   double dzBuyP(double& sourceArray[],double probabiltyValue, int lookBack, int bars, int i, double precision);
   double dzSellP(double& sourceArray[],double probabiltyValue, int lookBack, int bars, int i, double precision);
#import "spearman.dll"
   double rankSpearman(double& sourceArray[],bool isSeries, int rank, int bars, int i);
#import

//
//
//
//
//

extern string TimeFrame               = "Current time frame";
extern int    Rank                    = 14;
extern double SmoothLength            = 2.5;
extern double SmoothPhase             = 0;
extern bool   SmoothDouble            = true;
extern int    Price                   = PRICE_CLOSE;
extern int    DzLookBackBars          = 70;
extern double DzStartBuyProbability1  = 0.10;
extern double DzStartBuyProbability2  = 0.25;
extern double DzStartSellProbability1 = 0.10;
extern double DzStartSellProbability2 = 0.25;
extern bool   Interpolate             = true;



//
//
//
//
//

double rank[];
double bl1Buffer[];
double bl2Buffer[];
double sl1Buffer[];
double sl2Buffer[];
double zliBuffer[];
double prices[];



//
//
//
//
//

string indicatorFileName;
bool   returnBars;
bool   calculateValue;
int    timeFrame;



//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int init()
{
 
   SetIndexBuffer(0,rank);
   SetIndexBuffer(1,bl1Buffer);
   SetIndexBuffer(2,bl2Buffer);
   SetIndexBuffer(3,sl2Buffer);
   SetIndexBuffer(4,sl1Buffer);
   SetIndexBuffer(5,zliBuffer);
   
   Rank = MathMax(Rank,10);
   
   indicatorFileName = WindowExpertName();
   calculateValue    = TimeFrame=="calculateValue"; if (calculateValue) { return(0); }
   returnBars        = TimeFrame=="returnBars";     if (returnBars)     { return(0); }
   timeFrame         = stringToTimeFrame(TimeFrame);
   
      
          
   IndicatorShortName(timeFrameToString(timeFrame)+ " Double dynamic Spearman smooth (" + Rank + ")");
   return(0);
}


int deinit(){return(0);}


//
//
//
//
//

int start()
{
   double coef         = MathPow(Rank,3) - Rank;
   int    counted_bars = IndicatorCounted();
   int    i,k,r,n,limit;

   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
         limit = MathMin(Bars-counted_bars,Bars-1);
         if (returnBars) { rank[0] = MathMin(limit+1,Bars-1); return(0); }


   //
   //
   //
   //
   //
   
   if (calculateValue || timeFrame == Period())
   {
         

   if (ArraySize(prices)!= Bars) { ArrayResize(prices,Bars);}
   
      
      for(i = limit, r=Bars-i-1; i >= 0; i--,r++)
      {
         prices[r] = iMA(NULL,0,1,0,MODE_SMA,Price,i);
         rank[i]   = iDSmooth(rankSpearman(prices,false,Rank,Bars,i),SmoothLength,SmoothPhase,SmoothDouble,i,0);
         
     if (DzStartBuyProbability1 >0) bl1Buffer[i] = dzBuyP (rank, DzStartBuyProbability1,  DzLookBackBars, Bars, i, 0.0001);
     if (DzStartBuyProbability2 >0) bl2Buffer[i] = dzBuyP (rank, DzStartBuyProbability2,  DzLookBackBars, Bars, i, 0.0001);
     if (DzStartSellProbability1>0) sl1Buffer[i] = dzSellP(rank, DzStartSellProbability1, DzLookBackBars, Bars, i, 0.0001);
     if (DzStartSellProbability2>0) sl2Buffer[i] = dzSellP(rank, DzStartSellProbability2, DzLookBackBars, Bars, i, 0.0001);
                                    zliBuffer[i] = dzSellP(rank, 0.5                    , DzLookBackBars, Bars, i, 0.0001);
         
      }      
      
      return(0);
   }
   
   
   limit = MathMax(limit,MathMin(Bars,iCustom(NULL,timeFrame,indicatorFileName,"returnBars",0,0)*timeFrame/Period()));
         
   for (i=limit;i>=0; i--)
   {
      int y = iBarShift(NULL,timeFrame,Time[i]);
         rank[i]      = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",Rank,SmoothLength,SmoothPhase,SmoothDouble,Price,DzLookBackBars,DzStartBuyProbability1,DzStartBuyProbability2,DzStartSellProbability1,DzStartSellProbability2,0,y);
         bl1Buffer[i] = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",Rank,SmoothLength,SmoothPhase,SmoothDouble,Price,DzLookBackBars,DzStartBuyProbability1,DzStartBuyProbability2,DzStartSellProbability1,DzStartSellProbability2,1,y);
         bl2Buffer[i] = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",Rank,SmoothLength,SmoothPhase,SmoothDouble,Price,DzLookBackBars,DzStartBuyProbability1,DzStartBuyProbability2,DzStartSellProbability1,DzStartSellProbability2,2,y);
         sl2Buffer[i] = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",Rank,SmoothLength,SmoothPhase,SmoothDouble,Price,DzLookBackBars,DzStartBuyProbability1,DzStartBuyProbability2,DzStartSellProbability1,DzStartSellProbability2,3,y);
         sl1Buffer[i] = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",Rank,SmoothLength,SmoothPhase,SmoothDouble,Price,DzLookBackBars,DzStartBuyProbability1,DzStartBuyProbability2,DzStartSellProbability1,DzStartSellProbability2,4,y);
         zliBuffer[i] = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",Rank,SmoothLength,SmoothPhase,SmoothDouble,Price,DzLookBackBars,DzStartBuyProbability1,DzStartBuyProbability2,DzStartSellProbability1,DzStartSellProbability2,5,y); 
         
         
         
         if (!Interpolate || y==iBarShift(NULL,timeFrame,Time[i-1])) continue;

         //
         //
         //
         //
         //

         datetime time = iTime(NULL,timeFrame,y);
            for(n = 1; i+n < Bars && Time[i+n] >= time; n++) continue;	
            for(k = 1; k < n; k++)
            {
               rank[i+k]      = rank[i]      + (rank[i+n]     -rank[i])     *k/n;
               bl1Buffer[i+k] = bl1Buffer[i] + (bl1Buffer[i+n]-bl1Buffer[i])*k/n;
               bl2Buffer[i+k] = bl2Buffer[i] + (bl2Buffer[i+n]-bl2Buffer[i])*k/n;
               sl2Buffer[i+k] = sl2Buffer[i] + (sl2Buffer[i+n]-sl2Buffer[i])*k/n;
               sl1Buffer[i+k] = sl1Buffer[i] + (sl1Buffer[i+n]-sl1Buffer[i])*k/n;
               zliBuffer[i+k] = zliBuffer[i] + (zliBuffer[i+n]-zliBuffer[i])*k/n;
            }
   }

   //
   //
   //
   //
   //
   
   return(0);
}

string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int    iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};

//
//
//
//
//

int stringToTimeFrame(string tfs)
{
   tfs = stringUpperCase(tfs);
   for (int i=ArraySize(iTfTable)-1; i>=0; i--)
         if (tfs==sTfTable[i] || tfs==""+iTfTable[i]) return(MathMax(iTfTable[i],Period()));
                                                      return(Period());
}
string timeFrameToString(int tf)
{
   for (int i=ArraySize(iTfTable)-1; i>=0; i--) 
         if (tf==iTfTable[i]) return(sTfTable[i]);
                              return("");
}

//
//
//
//
//

string stringUpperCase(string str)
{
   string   s = str;

   for (int length=StringLen(str)-1; length>=0; length--)
   {
      int tchar = StringGetChar(s, length);
         if((tchar > 96 && tchar < 123) || (tchar > 223 && tchar < 256))
                     s = StringSetChar(s, length, tchar - 32);
         else if(tchar > -33 && tchar < 0)
                     s = StringSetChar(s, length, tchar + 224);
   }
   return(s);
}


double wrk[][20];

#define bsmax  5
#define bsmin  6
#define volty  7
#define vsum   8
#define avolty 9

//
//
//
//
//

double iDSmooth(double price, double length, double phase, bool isDouble, int i, int s=0)
{
   if (isDouble)
         return (iSmooth(iSmooth(price,MathSqrt(length),phase,i,s),MathSqrt(length),phase,i,s+10));
   else  return (iSmooth(price,length,phase,i,s));
}

//
//
//
//
//

double iSmooth(double price, double length, double phase, int i, int s=0)
{
   if (length <=1) return(price);
   if (ArrayRange(wrk,0) != Bars) ArrayResize(wrk,Bars);
   
   int r = Bars-i-1; 
      if (r==0) { for(int k=0; k<7; k++) wrk[r][k+s]=price; for(; k<10; k++) wrk[r][k+s]=0; return(price); }

   //
   //
   //
   //
   //
   
      double len1   = MathMax(MathLog(MathSqrt(0.5*(length-1)))/MathLog(2.0)+2.0,0);
      double pow1   = MathMax(len1-2.0,0.5);
      double del1   = price - wrk[r-1][bsmax+s];
      double del2   = price - wrk[r-1][bsmin+s];
      double div    = 1.0/(10.0+10.0*(MathMin(MathMax(length-10,0),100))/100);
      int    forBar = MathMin(r,10);
	
         wrk[r][volty+s] = 0;
               if(MathAbs(del1) > MathAbs(del2)) wrk[r][volty+s] = MathAbs(del1); 
               if(MathAbs(del1) < MathAbs(del2)) wrk[r][volty+s] = MathAbs(del2); 
         wrk[r][vsum+s] =	wrk[r-1][vsum+s] + (wrk[r][volty+s]-wrk[r-forBar][volty+s])*div;
         
         //
         //
         //
         //
         //
   
         wrk[r][avolty+s] = wrk[r-1][avolty+s]+(2.0/(MathMax(4.0*length,30)+1.0))*(wrk[r][vsum+s]-wrk[r-1][avolty+s]);
            if (wrk[r][avolty+s] > 0)
               double dVolty = wrk[r][volty+s]/wrk[r][avolty+s]; else dVolty = 0;   
	               if (dVolty > MathPow(len1,1.0/pow1)) dVolty = MathPow(len1,1.0/pow1);
                  if (dVolty < 1)                      dVolty = 1.0;

      //
      //
      //
      //
      //
	        
   	double pow2 = MathPow(dVolty, pow1);
      double len2 = MathSqrt(0.5*(length-1))*len1;
      double Kv   = MathPow(len2/(len2+1), MathSqrt(pow2));

         if (del1 > 0) wrk[r][bsmax+s] = price; else wrk[r][bsmax+s] = price - Kv*del1;
         if (del2 < 0) wrk[r][bsmin+s] = price; else wrk[r][bsmin+s] = price - Kv*del2;
	
   //
   //
   //
   //
   //
      
      double R     = MathMax(MathMin(phase,100),-100)/100.0 + 1.5;
      double beta  = 0.45*(length-1)/(0.45*(length-1)+2);
      double alpha = MathPow(beta,pow2);

         wrk[r][0+s] = price + alpha*(wrk[r-1][0+s]-price);
         wrk[r][1+s] = (price - wrk[r][0+s])*(1-beta) + beta*wrk[r-1][1+s];
         wrk[r][2+s] = (wrk[r][0+s] + R*wrk[r][1+s]);
         wrk[r][3+s] = (wrk[r][2+s] - wrk[r-1][4+s])*MathPow((1-alpha),2) + MathPow(alpha,2)*wrk[r-1][3+s];
         wrk[r][4+s] = (wrk[r-1][4+s] + wrk[r][3+s]); 

   //
   //
   //
   //
   //

   return(wrk[r][4+s]);
}