//+------------------------------------------------------------------+
//|                                                       vortex.mq4 |
//+------------------------------------------------------------------+
#property copyright "mladen"
#property link      "mladenfx@gmail.com"

#property indicator_separate_window
#property indicator_buffers 4
#property indicator_color1  DeepSkyBlue
#property indicator_color2  LimeGreen
#property indicator_color3  Red
#property indicator_color4  DimGray
#property indicator_width1  2
#property indicator_style4  STYLE_DOT

//
//
//
//
//

#import "dynamicZone.dll"
   double dzBuyP(double& sourceArray[],double probabiltyValue, int lookBack, int bars, int i, double precision);
   double dzSellP(double& sourceArray[],double probabiltyValue, int lookBack, int bars, int i, double precision);
#import

//
//
//
//
//

extern string TimeFrame              = "current time frame";
extern int    VortexPeriod           = 14;
extern double Smooth                 = 5;
extern double SmoothPhase            = 0;
extern int    DzLookBackBars         = 35;
extern double DzStartBuyProbability  = 0.10;
extern double DzStartSellProbability = 0.10;
extern bool   Interpolate            = true;

//
//
//
//
//

double vor[];
double zli[];
double bli[];
double sli[];
double work[][5];

string IndicatorFileName;
int    timeFrame;
bool   calculateValue;
bool   returnBars;


//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int init()
{
   SetIndexBuffer(0,vor);
   SetIndexBuffer(1,bli);
   SetIndexBuffer(2,sli);
   SetIndexBuffer(3,zli);
   
   //
   //
   //
   //
   //

      IndicatorFileName = WindowExpertName();
      calculateValue    = (TimeFrame=="calculateValue"); if (calculateValue) return(0);
      returnBars        = (TimeFrame=="returnBars");     if (returnBars)     return(0);
      timeFrame         = stringToTimeFrame(TimeFrame);

   //
   //
   //
   //
   //

   IndicatorShortName(timeFrameToString(timeFrame)+" Vortex ("+VortexPeriod+")");         
   return(0);
}
int deinit() {  return(0); }



//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

#define _rng 0
#define _vmp 1
#define _vmm 2
#define _vop 3
#define _vom 4

//
//
//
//
//

int start()
{
   int counted_bars=IndicatorCounted();
   int limit,i,r;

   if(counted_bars < 0)   return(-1);
   if(counted_bars > 0)   counted_bars--;
           limit = MathMin(Bars-counted_bars,Bars);
           if (returnBars)  { vor[0] = limit+1; return(0); }
           
   //
   //
   //
   //
   //

   if (calculateValue || timeFrame==Period())
   {
      if (ArrayRange(work,0) != Bars) ArrayResize(work,Bars);
   
      //
      //
      //
      //
      //
      
      for(i = limit, r = Bars-i-1; i >= 0; i--,r++)
      {
         work[r][_rng] = MathMax(High[i],Close[i+1])-MathMin(Low[i],Close[i+1]);
         work[r][_vmp] = MathAbs(High[i] - Low[i+1]);
         work[r][_vmm] = MathAbs(Low[i] - High[i+1]);
         work[r][_vop] = EMPTY_VALUE;
         work[r][_vom] = EMPTY_VALUE;

         if ((Bars-i)<VortexPeriod) continue;
         
         //
         //
         //
         //
         //
         
            double vmpSum = 0;
            double vmmSum = 0;
            double rngSum = 0;
            for (int k=0; k<VortexPeriod; k++)
            {
               vmpSum += work[r-k][_vmp];
               vmmSum += work[r-k][_vmm];
               rngSum += work[r-k][_rng];
            }
            if (rngSum !=0)
            {
               work[r][_vop] = vmpSum/rngSum;
               work[r][_vom] = vmmSum/rngSum;
            }
            
            //
            //
            //
            //
            //
            
            vor[i] = iSmooth(work[r][_vop]-work[r][_vom],Smooth,SmoothPhase,i);
            bli[i] = dzBuyP (vor, DzStartBuyProbability,  DzLookBackBars, Bars, i, 0.0001);
            sli[i] = dzSellP(vor, DzStartSellProbability, DzLookBackBars, Bars, i, 0.0001);
            zli[i] = dzSellP(vor, 0.5,                    DzLookBackBars, Bars, i, 0.0001);
      }
      return(0);
   }         
   
   //
   //
   //
   //
   //
   
   limit = MathMax(limit,MathMin(Bars,iCustom(NULL,timeFrame,IndicatorFileName,"returnBars",1,0)*timeFrame/Period()));
   for (i=limit;i>=0;i--)
   {
      int y = iBarShift(NULL,timeFrame,Time[i]);
         vor[i] = iCustom(NULL,timeFrame,IndicatorFileName,"calculateValue",VortexPeriod,Smooth,SmoothPhase,DzLookBackBars,DzStartBuyProbability,DzStartSellProbability,0,y);
         bli[i] = iCustom(NULL,timeFrame,IndicatorFileName,"calculateValue",VortexPeriod,Smooth,SmoothPhase,DzLookBackBars,DzStartBuyProbability,DzStartSellProbability,1,y);
         sli[i] = iCustom(NULL,timeFrame,IndicatorFileName,"calculateValue",VortexPeriod,Smooth,SmoothPhase,DzLookBackBars,DzStartBuyProbability,DzStartSellProbability,2,y);
         zli[i] = iCustom(NULL,timeFrame,IndicatorFileName,"calculateValue",VortexPeriod,Smooth,SmoothPhase,DzLookBackBars,DzStartBuyProbability,DzStartSellProbability,3,y);

         //
         //
         //
         //
         //
      
         if (!Interpolate || y==iBarShift(NULL,timeFrame,Time[i-1])) continue;

         //
         //
         //
         //
         //

         datetime time = iTime(NULL,timeFrame,y);
            for(int n = 1; i+n < Bars && Time[i+n] >= time; n++) continue;	
            for(k = 1; k < n; k++)
            {
               vor[i+k] = vor[i] + (vor[i+n] - vor[i])*k/n;
               bli[i+k] = bli[i] + (bli[i+n] - bli[i])*k/n;
               sli[i+k] = sli[i] + (sli[i+n] - sli[i])*k/n;
               zli[i+k] = zli[i] + (zli[i+n] - zli[i])*k/n;
            }               
   }

   //
   //
   //
   //
   //

   return(0);      
}

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int    iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};

//
//
//
//
//

int stringToTimeFrame(string tfs)
{
   tfs = StringUpperCase(tfs);
   for (int i=ArraySize(iTfTable)-1; i>=0; i--)
         if (tfs==sTfTable[i] || tfs==""+iTfTable[i]) return(MathMax(iTfTable[i],Period()));
                                                      return(Period());
}
string timeFrameToString(int tf)
{
   for (int i=ArraySize(iTfTable)-1; i>=0; i--) 
         if (tf==iTfTable[i]) return(sTfTable[i]);
                              return("");
}

//
//
//
//
//

string StringUpperCase(string str)
{
   string   s = str;

   for (int length=StringLen(str)-1; length>=0; length--)
   {
      int tchar = StringGetChar(s, length);
         if((tchar > 96 && tchar < 123) || (tchar > 223 && tchar < 256))
                     s = StringSetChar(s, length, tchar - 32);
         else if(tchar > -33 && tchar < 0)
                     s = StringSetChar(s, length, tchar + 224);
   }
   return(s);
}

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

double wrk[][10];

#define bsmax  5
#define bsmin  6
#define volty  7
#define vsum   8
#define avolty 9

//
//
//
//
//

double iSmooth(double price, double length, double phase, int i, int s=0)
{
   if (length <=1) return(price);
   if (ArrayRange(wrk,0) != Bars) ArrayResize(wrk,Bars);
   
   int r = Bars-i-1; 
      if (r==0) { for(int k=0; k<7; k++) wrk[r][k+s]=price; for(; k<10; k++) wrk[r][k+s]=0; return(price); }

   //
   //
   //
   //
   //
   
      double len1   = MathMax(MathLog(MathSqrt(0.5*(length-1)))/MathLog(2.0)+2.0,0);
      double pow1   = MathMax(len1-2.0,0.5);
      double del1   = price - wrk[r-1][bsmax+s];
      double del2   = price - wrk[r-1][bsmin+s];
      double div    = 1.0/(10.0+10.0*(MathMin(MathMax(length-10,0),100))/100);
      int    forBar = MathMin(r,10);
	
         wrk[r][volty+s] = 0;
               if(MathAbs(del1) > MathAbs(del2)) wrk[r][volty+s] = MathAbs(del1); 
               if(MathAbs(del1) < MathAbs(del2)) wrk[r][volty+s] = MathAbs(del2); 
         wrk[r][vsum+s] =	wrk[r-1][vsum+s] + (wrk[r][volty+s]-wrk[r-forBar][volty+s])*div;
         
         //
         //
         //
         //
         //
   
         wrk[r][avolty+s] = wrk[r-1][avolty+s]+(2.0/(MathMax(4.0*length,30)+1.0))*(wrk[r][vsum+s]-wrk[r-1][avolty+s]);
            if (wrk[r][avolty+s] > 0)
               double dVolty = wrk[r][volty+s]/wrk[r][avolty+s]; else dVolty = 0;   
	               if (dVolty > MathPow(len1,1.0/pow1)) dVolty = MathPow(len1,1.0/pow1);
                  if (dVolty < 1)                      dVolty = 1.0;

      //
      //
      //
      //
      //
	        
   	double pow2 = MathPow(dVolty, pow1);
      double len2 = MathSqrt(0.5*(length-1))*len1;
      double Kv   = MathPow(len2/(len2+1), MathSqrt(pow2));

         if (del1 > 0) wrk[r][bsmax+s] = price; else wrk[r][bsmax+s] = price - Kv*del1;
         if (del2 < 0) wrk[r][bsmin+s] = price; else wrk[r][bsmin+s] = price - Kv*del2;
	
   //
   //
   //
   //
   //
      
      double R     = MathMax(MathMin(phase,100),-100)/100.0 + 1.5;
      double beta  = 0.45*(length-1)/(0.45*(length-1)+2);
      double alpha = MathPow(beta,pow2);

         wrk[r][0+s] = price + alpha*(wrk[r-1][0+s]-price);
         wrk[r][1+s] = (price - wrk[r][0+s])*(1-beta) + beta*wrk[r-1][1+s];
         wrk[r][2+s] = (wrk[r][0+s] + R*wrk[r][1+s]);
         wrk[r][3+s] = (wrk[r][2+s] - wrk[r-1][4+s])*MathPow((1-alpha),2) + MathPow(alpha,2)*wrk[r-1][3+s];
         wrk[r][4+s] = (wrk[r-1][4+s] + wrk[r][3+s]); 

   //
   //
   //
   //
   //

   return(wrk[r][4+s]);
}