//------------------------------------------------------------------
#property copyright "copyright mladen"
#property link      "mladenfx@gmail.com"
//------------------------------------------------------------------
#property indicator_chart_window
#property indicator_buffers 3
#property indicator_color1  Lime
#property indicator_color2  Silver
#property indicator_color3  Orange
#property indicator_style2  STYLE_DOT

//
//
//
//
//

extern int    Average         = 8;
extern int    VolPeriod       = 13;
extern double DeviationFactor = 3.55;
extern double LowerBandAdjust = 0.9; 
extern int    Price           = PRICE_TYPICAL;
                             
double bufferUp[];
double bufferMi[];
double bufferDn[];
double prices[];
double typical[];

//------------------------------------------------------------------
//
//------------------------------------------------------------------
//
//
//
//
//

int init()
{
   IndicatorBuffers(5);
   SetIndexBuffer(0,bufferUp);
   SetIndexBuffer(1,bufferMi);
   SetIndexBuffer(2,bufferDn);
   SetIndexBuffer(3,prices);
   SetIndexBuffer(4,typical);
   return(0);
}
int deinit() { return(0); }
int start()
{
   int counted_bars=IndicatorCounted();
      if(counted_bars<0) return(-1);
      if(counted_bars>0) counted_bars--;
         int limit = MathMin(Bars-counted_bars,Bars-1);

   //
   //
   //
   //
   //

   for(int i=limit; i>=0; i--)
   {
      prices[i] = iMA(NULL,0,1,0,MODE_SMA,Price,i);
      if (prices[i]>prices[i+1])
            typical[i] = prices[i]-Low[i+1];
      else  typical[i] = prices[i+1]-Low[i];
      
      //
      //
      //
      //
      //
      
      double dev = typical[i];
         for (int k=1; k<VolPeriod; k++) dev += typical[i+k];
                                         dev  = dev/VolPeriod*DeviationFactor;
      double devHigh = iEma(dev,Average,i,0);
      double devLow  = iEma(dev,Average,i,1)*LowerBandAdjust;
      double medAvg  = iEma(prices[i],Average,i,2);
      bufferMi[i] = iSma(medAvg,Average,i);
      bufferUp[i] = iEma(medAvg,Average,i,3)+devHigh;
      bufferDn[i] = iEma(medAvg,Average,i,4)-devLow;
   }
   return(0);
}  


//------------------------------------------------------------------
//                                                                  
//------------------------------------------------------------------
//
//
//
//
//

double workSma[][2];
double iSma(double price, int period, int r, int instanceNo=0)
{
   if (ArrayRange(workSma,0)!= Bars) ArrayResize(workSma,Bars); instanceNo *= 2; r=Bars-r-1;

   //
   //
   //
   //
   //
      
   workSma[r][instanceNo] = price;
   if (r>=period)
          workSma[r][instanceNo+1] = workSma[r-1][instanceNo+1]+(workSma[r][instanceNo]-workSma[r-period][instanceNo])/period;
   else { workSma[r][instanceNo+1] = 0; for(int k=0; k<period && (r-k)>=0; k++) workSma[r][instanceNo+1] += workSma[r-k][instanceNo];  
          workSma[r][instanceNo+1] /= k; }
   return(workSma[r][instanceNo+1]);
}

//
//
//
//
//

double workEma[][5];
double iEma(double price, double period, int r, int instanceNo=0)
{
   if (ArrayRange(workEma,0)!= Bars) ArrayResize(workEma,Bars); r=Bars-r-1;

   //
   //
   //
   //
   //
      
   double alpha = 2.0 / (1.0+period);
          workEma[r][instanceNo] = workEma[r-1][instanceNo]+alpha*(price-workEma[r-1][instanceNo]);
   return(workEma[r][instanceNo]);
}