//+------------------------------------------------------------------+
//|                                                              rsx |
//|                                                           mladen |
//+------------------------------------------------------------------+
#property copyright "mladen"
#property link      "mladenfx@gmail.com"

//
//
//
//
//

#property indicator_separate_window
#property indicator_buffers    4
#property indicator_color1     Green
#property indicator_color2     Crimson
#property indicator_color3     Crimson
#property indicator_color4     Gold
#property indicator_width1     2
#property indicator_width2     2
#property indicator_width3     2
#property indicator_width4     1
#property indicator_minimum    0
#property indicator_maximum    100
#property indicator_level1     80
#property indicator_level2     50
#property indicator_level3     20
#property indicator_levelcolor MediumOrchid

//
//
//
//
//

extern string ote_TimeFrames           = "M1;5,15,30,60H1;240H4;1440D1;10080W1;43200MN|0-CurrentTF";
extern string TimeFrame                = "Current time frame";
extern int    ShortLimit               = 10;
extern int    LongLimit                = 20;
extern int    CfbNormLength            = 50;
extern int    CfbDepth                 = 3;
extern int    CfbPrice                 = PRICE_WEIGHTED;
extern int    CfbSmooth                = 8;
extern double CfbResultSmooth          = 2.00;
extern double CfbResultSmoothPhase     = 0.0;
extern bool   CfbResultSmoothDouble    = true;
extern double Length                   = 34;
extern double Phase                    = 0;
extern bool   SmoothDouble             = true;
extern bool   Interpolate              = true;
extern bool   MultiColor               = true;

extern bool   alertsOn                 = true;
extern bool   alertsOnRsxSlope         = true;
extern bool   alertsOnRsxJMaCross      = true;
extern bool   alertsRsxSlopeRsxJMaCross= true;
extern bool   alertsOnCurrent          = false;
extern bool   alertsMessage            = true;
extern bool   alertsSound              = true;
extern bool   alertsEmail              = false;
//
//
//
//
//

double rsx[];
double rsxUa[];
double rsxUb[];
double rsxjma[];
double cfb[];
double slope[];
double wrkBuffer[][13];
double trends[][3];

#define _tup1 0
#define _tdn1 1
#define _tmi1 2

//
//
//
//
//

string indicatorFileName;
bool   calculateValue;
bool   returnBars;
int    timeFrame;

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int init()
{
   IndicatorBuffers(6);
     SetIndexBuffer(0,rsx); SetIndexLabel(0,"RSX");
     SetIndexBuffer(1,rsxUa);
     SetIndexBuffer(2,rsxUb);
     SetIndexBuffer(3,rsxjma);
     SetIndexBuffer(4,cfb);
     SetIndexBuffer(5,slope);
     
     //
     //
     //
     //
     //
     
     indicatorFileName = WindowExpertName();
     calculateValue    = (TimeFrame=="calculateValue"); if (calculateValue) return(0);
     returnBars        = (TimeFrame=="returnBars");     if (returnBars)     return(0);
     timeFrame         = stringToTimeFrame(TimeFrame);
     
     //
     //
     //
     //
     //
     
     IndicatorShortName(timeFrameToString(timeFrame)+ " Cfb adaptive Rsx Ma ("+ShortLimit+","+LongLimit+")");
   
     return(0);
}

//
//
//
//
//

int deinit() { return(0); }

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int start()
{
   int counted_bars=IndicatorCounted();
   int i,r,n,limit;

   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
         limit = Bars-counted_bars;
         if (ArrayRange(wrkBuffer,0) != Bars) ArrayResize(wrkBuffer,Bars);
         if (returnBars) { rsx[0] = limit+1; return(0); }
   //
   //
   //
   //
   //
   
   if (calculateValue || timeFrame == Period())
   {
   
   if (ArrayRange(trends,0)!=Bars) {  ArrayResize(trends,Bars); }
   
   if (MultiColor && !calculateValue && slope[limit]==-1) CleanPoint(limit,rsxUa,rsxUb);

   //
   //
   //
   //
   //

   for(i=limit, r=Bars-i-1; i>=0; i--, r++)
   {
      wrkBuffer[r][12] = iMA(NULL,0,1,0,MODE_SMA,PRICE_CLOSE,i);

         if (i==(Bars-1)) { for (int c=0; c<12; c++) wrkBuffer[r][c] = 0; continue; }  

      

         cfb[i] = iDSmooth(iCfb(Bars,iMA(NULL,0,1,0,MODE_SMA,CfbPrice,i),CfbDepth,CfbSmooth,r),CfbResultSmooth,CfbResultSmoothPhase,CfbResultSmoothDouble,i);
         
         double cfbMax = cfb[i];
         double cfbMin = cfb[i];
         for (int k=1; k<CfbNormLength && (i+k)<Bars; k++ )
         {
                cfbMax = MathMax(cfb[i+k],cfbMax);
                cfbMin = MathMin(cfb[i+k],cfbMin);
         }
         double denominator = cfbMax-cfbMin;
         if (denominator> 0)
         double ratio = (cfb[i]-cfbMin)/denominator;
         else      ratio = 0.5; 
         
         //
         //
         //
         //
         //                
   
         double RsxLength  = MathCeil(ShortLimit+ratio*(LongLimit-ShortLimit));
         double Kg         = (3.0)/(2.0+RsxLength);
         double Hg         = 1.0-Kg;
         double roc        = wrkBuffer[r][12]-wrkBuffer[r-1][12];
         double roa        = MathAbs(roc);
         
         for (k=0; k<3; k++)
         {
        
         int kk = k*2;
             wrkBuffer[r][kk+0] = Kg*roc                + Hg*wrkBuffer[r-1][kk+0];
             wrkBuffer[r][kk+1] = Kg*wrkBuffer[r][kk+0] + Hg*wrkBuffer[r-1][kk+1]; roc = 1.5*wrkBuffer[r][kk+0] - 0.5 * wrkBuffer[r][kk+1];
             wrkBuffer[r][kk+6] = Kg*roa                + Hg*wrkBuffer[r-1][kk+6];
             wrkBuffer[r][kk+7] = Kg*wrkBuffer[r][kk+6] + Hg*wrkBuffer[r-1][kk+7]; roa = 1.5*wrkBuffer[r][kk+6] - 0.5 * wrkBuffer[r][kk+7];
         }
        
         if (roa != 0)
              rsx[i]   = MathMax(MathMin((roc/roa+1.0)*50.0,100.00),0.00); 
         else rsx[i]   = 50.0;
         }
         
         //
         //
         //
         //
         //
         
         for(i=limit, r=Bars-i-1; i>=0; i--, r++)
         {
              rsxjma[i] = iDSmooth(rsx[i],Length,Phase,SmoothDouble,i, 20);
              rsxUa[i]  = EMPTY_VALUE;
              rsxUb[i]  = EMPTY_VALUE;
              slope[i]  = slope[i+1];
 
         if (rsx[i] > rsx[i+1]) slope[i]= 1;
         if (rsx[i] < rsx[i+1]) slope[i]=-1;
         if (MultiColor && !calculateValue && slope[i]==-1) PlotPoint(i,rsxUa,rsxUb,rsx);
      
         setTrends(i,r);
       
         }
     
         manageAlerts();
         return(0);
         }
           
         //
         //
         //
         //
         //
     
         limit = MathMax(limit,MathMin(Bars,iCustom(NULL,timeFrame,indicatorFileName,"returnBars",0,0)*timeFrame/Period()));
        
         if (MultiColor && slope[limit]==-1) CleanPoint(limit,rsxUa,rsxUb);
   
         for(i = limit, r=Bars-i-1; i>=0; i--,r++)
         {
                 int y    = iBarShift(NULL,timeFrame,Time[i]);
                     rsx[i]    = iCustom(NULL,timeFrame,indicatorFileName,"","calculateValue",ShortLimit,LongLimit,CfbNormLength,CfbDepth,CfbPrice,CfbSmooth,CfbResultSmooth,CfbResultSmoothPhase,CfbResultSmoothDouble,Length,Phase,SmoothDouble,0,y);
                     rsxUa[i]  = EMPTY_VALUE;
                     rsxUb[i]  = EMPTY_VALUE;
                     rsxjma[i] = iCustom(NULL,timeFrame,indicatorFileName,"","calculateValue",ShortLimit,LongLimit,CfbNormLength,CfbDepth,CfbPrice,CfbSmooth,CfbResultSmooth,CfbResultSmoothPhase,CfbResultSmoothDouble,Length,Phase,SmoothDouble,3,y);
                     slope[i]  = iCustom(NULL,timeFrame,indicatorFileName,"","calculateValue",ShortLimit,LongLimit,CfbNormLength,CfbDepth,CfbPrice,CfbSmooth,CfbResultSmooth,CfbResultSmoothPhase,CfbResultSmoothDouble,Length,Phase,SmoothDouble,5,y);
    
                     setTrends(i,r);
    
                     //
                     //
                     //
                     //
                     //
            
                     if (!Interpolate || y==iBarShift(NULL,timeFrame,Time[i-1])) continue;

                     //
                     //
                     //
                     //
                     //

                     datetime time = iTime(NULL,timeFrame,y);
                     for(n = 1; i+n < Bars && Time[i+n] >= time; n++) continue;	
                     for(k = 1; k < n; k++)
                     {
                    
  	                      rsx[i+k]    = rsx[i]     + (rsx[i+n]   - rsx[i])   * k/n;
  	                      rsxjma[i+k] = rsxjma[i] + (rsxjma[i+n] - rsxjma[i])* k/n;
            
                     }  	            
                     }
                    
                     //
                     //
                     //
                     //
                     //
                    
                     if (MultiColor) for (i=limit;i>=0;i--) if (slope[i]==-1) PlotPoint(i,rsxUa,rsxUb,rsx);
                     
      
          manageAlerts();
             
   return(0);
}

//
// 
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+

void setTrends(int i, int r)
{
   
   trends[r][_tup1] = trends[r-1][_tup1];
   trends[r][_tdn1] = trends[r-1][_tdn1];
   trends[r][_tmi1] = trends[r-1][_tmi1];

      if (rsx[i] > rsx[i+1])                                                  trends[r][_tup1] =  1;
      if (rsx[i] < rsx[i+1])                                                  trends[r][_tup1] = -1;
      if (rsx[i] > rsxjma[i] && rsx[i+1] <= rsxjma[i+1])                      trends[r][_tdn1] =  1;
      if (rsx[i] < rsxjma[i] && rsx[i+1] >= rsxjma[i+1])                      trends[r][_tdn1] = -1;
      if (rsx[i] > rsx[i+1] && rsx[i] > rsxjma[i] && rsx[i+1] <= rsxjma[i+1]) trends[r][_tmi1] =  1;
      if (rsx[i] < rsx[i+1] && rsx[i] < rsxjma[i] && rsx[i+1] >= rsxjma[i+1]) trends[r][_tmi1] = -1;
                           
}

//
//
//
//
//

void manageAlerts()
{
   if (!calculateValue && alertsOn)
   {
      if (alertsOnCurrent)
           int whichBar = 0;
      else     whichBar = 1; whichBar = iBarShift(NULL,0,iTime(NULL,timeFrame,whichBar)); 
                             whichBar = Bars-whichBar-1;

      //
      //
      //
      //
      //
            
      static datetime time1 = 0;
      static string   mess1 = "";
      if (alertsOnRsxSlope && trends[whichBar][_tup1] != trends[whichBar-1][_tup1])
      {
         if (trends[whichBar][_tup1] ==  1) doAlert(time1,mess1,whichBar,"up slope");
         if (trends[whichBar][_tup1] == -1) doAlert(time1,mess1,whichBar,"down slope");
      }
      static datetime time2 = 0;
      static string   mess2 = "";
      if (alertsOnRsxJMaCross && trends[whichBar][_tdn1] != trends[whichBar-1][_tdn1])
      {
         if (trends[whichBar][_tdn1] ==  1) doAlert(time2,mess2,whichBar,"bullish cross");
         if (trends[whichBar][_tdn1] == -1) doAlert(time2,mess2,whichBar,"bearish cross");
      }
      static datetime time3 = 0;
      static string   mess3 = "";
      if (alertsRsxSlopeRsxJMaCross && trends[whichBar][_tmi1] != trends[whichBar-1][_tmi1])
      {
         if (trends[whichBar][_tmi1] ==  1) doAlert(time3,mess3,whichBar,"bullish cross and slope");
         if (trends[whichBar][_tmi1] == -1) doAlert(time3,mess3,whichBar,"bearish cross and slope");
      }
   }
}

//
//
//
//
//

void doAlert(datetime& previousTime, string& previousAlert, int forBar, string doWhat)
{
   string message;
   
   if (previousAlert != doWhat || previousTime != Time[forBar]) {
       previousAlert  = doWhat;
       previousTime   = Time[forBar];

       //
       //
       //
       //
       //

       message =  StringConcatenate(Symbol()," ",timeFrameToString(timeFrame)," at ",TimeToStr(TimeLocal(),TIME_SECONDS)," Cfb rsx ma ",doWhat);
          if (alertsMessage) Alert(message);
          if (alertsEmail)   SendMail(StringConcatenate(Symbol()," Cfb rsx ma "),message);
          if (alertsSound)   PlaySound("alert2.wav");
   }
}

//+-------------------------------------------------------------------
//|                                                                  
//+-------------------------------------------------------------------
//
//
//
//
//

void CleanPoint(int i,double& first[],double& second[])
{
   if ((second[i]  != EMPTY_VALUE) && (second[i+1] != EMPTY_VALUE))
        second[i+1] = EMPTY_VALUE;
   else
      if ((first[i] != EMPTY_VALUE) && (first[i+1] != EMPTY_VALUE) && (first[i+2] == EMPTY_VALUE))
          first[i+1] = EMPTY_VALUE;
}

//
//
//
//
//

void PlotPoint(int i,double& first[],double& second[],double& from[])
{
   if (first[i+1] == EMPTY_VALUE)
      {
         if (first[i+2] == EMPTY_VALUE) {
                first[i]   = from[i];
                first[i+1] = from[i+1];
                second[i]  = EMPTY_VALUE;
            }
         else {
                second[i]   =  from[i];
                second[i+1] =  from[i+1];
                first[i]    = EMPTY_VALUE;
            }
      }
   else
      {
         first[i]  = from[i];
         second[i] = EMPTY_VALUE;
      }
}
  

string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int    iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};

//
//
//
//
//

int stringToTimeFrame(string tfs)
{
   tfs = stringUpperCase(tfs);
   for (int i=ArraySize(iTfTable)-1; i>=0; i--)
         if (tfs==sTfTable[i] || tfs==""+iTfTable[i]) return(MathMax(iTfTable[i],Period()));
                                                      return(Period());
}
string timeFrameToString(int tf)
{
   for (int i=ArraySize(iTfTable)-1; i>=0; i--) 
         if (tf==iTfTable[i]) return(sTfTable[i]);
                              return("");
}

//
//
//
//
//

string stringUpperCase(string str)
{
   string   s = str;

   for (int length=StringLen(str)-1; length>=0; length--)
   {
      int tchar = StringGetChar(s, length);
         if((tchar > 96 && tchar < 123) || (tchar > 223 && tchar < 256))
                     s = StringSetChar(s, length, tchar - 32);
         else if(tchar > -33 && tchar < 0)
                     s = StringSetChar(s, length, tchar + 224);
   }
   return(s);
}

//
//
//
//
//

int    Depths[] = {2,3,4,6,8,12,16,24,32,48,64,96,128,192};
double workCfb[][28];

//
//
//
//
//

double iCfb(int totalBars, double price, int depth, int smooth, int i)
{
   if (ArrayRange(workCfb,0) != totalBars) ArrayResize(workCfb,totalBars);
         
   //
   //
   //
   //
   //

   double suma     = 0;
   double sumb     = 0;
   double cfb      = 0;
   double evenCoef = 1;
   double oddCoef  = 1;
   double avg      = 0;
         
      if (i>=smooth)
         for (int k=depth-1; k>=0; k--)
         {
            workCfb[i][k]    = iCfbFunc(totalBars,price,i,Depths[k],k);
            workCfb[i][k+14] = workCfb[i-1][k+14] + (workCfb[i][k]-workCfb[i-smooth][k])/smooth;

                  if ((k%2)==0)
                        { avg = oddCoef  * workCfb[i][k+14]; oddCoef  = oddCoef  * (1 - avg); }
                  else  { avg = evenCoef * workCfb[i][k+14]; evenCoef = evenCoef * (1 - avg); }
               
               suma += avg*avg*Depths[k];
               sumb += avg;
         }
      else for (k=depth-1; k>=0; k--) { workCfb[i][k] = 0; workCfb[i][k+14] = 0; }            

   //
   //
   //
   //
   //

   if (sumb != 0) cfb = suma/sumb;
   return(cfb);
}

//+------------------------------------------------------------------
//|                                                                  
//+------------------------------------------------------------------
//
//
//
//
//

double  workCfbFunc[][70];
#define _prices 0
#define _roc    1
#define _value1 2
#define _value2 3
#define _value3 4

//
//
//
//

double iCfbFunc(int totalBars, double price, int r, int depth, int k)
{
   k *= 5;
      if (ArrayRange(workCfbFunc,0) != totalBars) ArrayResize(workCfbFunc,totalBars);
      if (r<=(depth+1))
      {
         workCfbFunc[r][k+_prices] = 0;
         workCfbFunc[r][k+_roc]    = 0;
         workCfbFunc[r][k+_value1] = 0;
         workCfbFunc[r][k+_value2] = 0;
         workCfbFunc[r][k+_value3] = 0;
         return(0);
      }         
      workCfbFunc[r][k+_prices] = price; 

   //
   //
   //
   //
   //

      workCfbFunc[r][k+_roc]    = MathAbs(workCfbFunc[r][k+_prices] - workCfbFunc[r-1][k+_prices]);
      workCfbFunc[r][k+_value1] = workCfbFunc[r-1][k+_value1] - workCfbFunc[r-depth][k+_roc] + workCfbFunc[r][k+_roc];
      workCfbFunc[r][k+_value2] = workCfbFunc[r-1][k+_value2] - workCfbFunc[r-1][k+_value1] + workCfbFunc[r][k+_roc]*depth;
      workCfbFunc[r][k+_value3] = workCfbFunc[r-1][k+_value3] - workCfbFunc[r-1-depth][k+_prices] + workCfbFunc[r-1][k+_prices];
   
      double dividend = MathAbs(depth*workCfbFunc[r][k+_prices]-workCfbFunc[r][k+_value3]);

      //
      //
      //
      //
      //
         
   if (workCfbFunc[r][k+_value2] != 0)
         return( dividend / workCfbFunc[r][k+_value2]);
   else  return(0.00);            
}

//+------------------------------------------------------------------
//|                                                                  
//+------------------------------------------------------------------
//
//
//
//
//

double wrk[][40];

#define bsmax  5
#define bsmin  6
#define volty  7
#define vsum   8
#define avolty 9

//
//
//
//
//

double iDSmooth(double price, double length, double phase, bool isDouble, int i, int s=0)
{
   if (isDouble)
         return (iSmooth(iSmooth(price,MathSqrt(length),phase,i,s),MathSqrt(length),phase,i,s+10));
   else  return (iSmooth(price,length,phase,i,s));
}

//
//
//
//
//

double iSmooth(double price, double length, double phase, int i, int s=0)
{
   if (length <=1) return(price);
   if (ArrayRange(wrk,0) != Bars) ArrayResize(wrk,Bars);
   
   int r = Bars-i-1; 
      if (r==0) { for(int k=0; k<7; k++) wrk[r][k+s]=price; for(; k<10; k++) wrk[r][k+s]=0; return(price); }

   //
   //
   //
   //
   //
   
      double len1   = MathMax(MathLog(MathSqrt(0.5*(length-1)))/MathLog(2.0)+2.0,0);
      double pow1   = MathMax(len1-2.0,0.5);
      double del1   = price - wrk[r-1][bsmax+s];
      double del2   = price - wrk[r-1][bsmin+s];
      double div    = 1.0/(10.0+10.0*(MathMin(MathMax(length-10,0),100))/100);
      int    forBar = MathMin(r,10);
	
         wrk[r][volty+s] = 0;
               if(MathAbs(del1) > MathAbs(del2)) wrk[r][volty+s] = MathAbs(del1); 
               if(MathAbs(del1) < MathAbs(del2)) wrk[r][volty+s] = MathAbs(del2); 
         wrk[r][vsum+s] =	wrk[r-1][vsum+s] + (wrk[r][volty+s]-wrk[r-forBar][volty+s])*div;
         
         //
         //
         //
         //
         //
   
         wrk[r][avolty+s] = wrk[r-1][avolty+s]+(2.0/(MathMax(4.0*length,30)+1.0))*(wrk[r][vsum+s]-wrk[r-1][avolty+s]);
            if (wrk[r][avolty+s] > 0)
               double dVolty = wrk[r][volty+s]/wrk[r][avolty+s]; else dVolty = 0;   
	               if (dVolty > MathPow(len1,1.0/pow1)) dVolty = MathPow(len1,1.0/pow1);
                  if (dVolty < 1)                      dVolty = 1.0;

      //
      //
      //
      //
      //
	        
   	double pow2 = MathPow(dVolty, pow1);
      double len2 = MathSqrt(0.5*(length-1))*len1;
      double Kv   = MathPow(len2/(len2+1), MathSqrt(pow2));

         if (del1 > 0) wrk[r][bsmax+s] = price; else wrk[r][bsmax+s] = price - Kv*del1;
         if (del2 < 0) wrk[r][bsmin+s] = price; else wrk[r][bsmin+s] = price - Kv*del2;
	
   //
   //
   //
   //
   //
      
      double R     = MathMax(MathMin(phase,100),-100)/100.0 + 1.5;
      double beta  = 0.45*(length-1)/(0.45*(length-1)+2);
      double alpha = MathPow(beta,pow2);

         wrk[r][0+s] = price + alpha*(wrk[r-1][0+s]-price);
         wrk[r][1+s] = (price - wrk[r][0+s])*(1-beta) + beta*wrk[r-1][1+s];
         wrk[r][2+s] = (wrk[r][0+s] + R*wrk[r][1+s]);
         wrk[r][3+s] = (wrk[r][2+s] - wrk[r-1][4+s])*MathPow((1-alpha),2) + MathPow(alpha,2)*wrk[r-1][3+s];
         wrk[r][4+s] = (wrk[r-1][4+s] + wrk[r][3+s]); 

   //
   //
   //
   //
   //

   return(wrk[r][4+s]);
}