//+------------------------------------------------------------------+
//|                                                  cfb channel.mq4 |
//|                                                           mladen |
//|                                               mladenfx@gmail.com |
//+------------------------------------------------------------------+
#property copyright "mladen"
#property link      "mladenfx@gmail.com"

#property indicator_chart_window
#property indicator_buffers 3
#property indicator_color1  DeepSkyBlue
#property indicator_color2  Gold
#property indicator_color3  PaleVioletRed
#property indicator_style1  STYLE_DOT
#property indicator_style2  STYLE_DASH
#property indicator_style3  STYLE_DOT

//
//
//
//
//
extern string TimeFrame             = "current time frame";
extern int    CfbDepth              = 1;
extern int    CfbPrice              = PRICE_WEIGHTED;
extern int    CfbNormalizePeriod    = 50;
extern int    CfbSmooth             = 8;
extern double CfbResultSmooth       = 5;
extern double CfbResultSmoothPhase  = 0.0;
extern bool   CfbResultSmoothDouble = true;
extern int    Depth1                = 10;
extern int    Depth2                = 20;
extern bool   Interpolate           = true;

//
//
//
//
//

double buffer1[];
double buffer2[];
double buffer3[];
int    Ignore;



string indicatorFileName;
bool   calculateCfb;
bool   returnBars;
int    timeFrame;


//
//
//
//
//

int init()
{
   SetIndexBuffer(0,buffer1);
   SetIndexBuffer(1,buffer2);
   SetIndexBuffer(2,buffer3);
   
   int    Depths[] = {24,32,48,64,96,128,192};
   
   CfbDepth = MathMax(MathMin(CfbDepth,7),1)+7;
   Ignore   = Depths[CfbDepth-8]+3;
   
   indicatorFileName = WindowExpertName();
   returnBars        = TimeFrame=="returnBars";   if (returnBars)     return(0);
   calculateCfb      = TimeFrame=="calculateCfb"; if (calculateCfb) return(0);
   timeFrame         = stringToTimeFrame(TimeFrame);
   
   IndicatorShortName(timeFrameToString(timeFrame)+ " cfb channel on ds jurik");
      
   
   
   return(0);
}
int deinit() { return(0); }

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

double work[][1];
#define _cfb 0

//
//
//
//
//

int start()
{
   int i,r,n,depth,limit,counted_bars  = IndicatorCounted();
   
   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
       limit = MathMin(Bars - counted_bars,Bars-1);
       if (returnBars)  { buffer1[0] = limit+1; return(0); }
       if (ArrayRange(work,0)!=Bars) ArrayResize(work,Bars);

   //
   //
   //
   if (calculateCfb || timeFrame==Period())
   {
   

   for(i = limit,r=Bars-i-1; i >= 0 ; i--,r++)
   {
      double ratio = 0;
      double cfb   = iDSmooth(iCfb(Bars,iMA(NULL,0,1,0,MODE_SMA,CfbPrice,i),CfbDepth,CfbSmooth,r),CfbResultSmooth,CfbResultSmoothPhase,CfbResultSmoothDouble,i);

      //
      //
      //
      //
      //
         
         work[r][_cfb] = cfb;
            double max = cfb;
            double min = cfb;
            if (r>=Ignore)
               for (int k=1; k<CfbNormalizePeriod && (r-k)>=0; k++)
                  {
                     min = MathMin(work[r-k][_cfb],min);
                     max = MathMax(work[r-k][_cfb],max);
                  }
            if (min!=max)
                  ratio = (cfb-min)/(max-min);
                  depth = MathRound( Depth1 + ratio*(Depth2-Depth1));
 
      //
      //
      //
      //
      //
         
         if (High[i] > buffer1[i+1])
               buffer1[i] =  High[i];
         else  buffer1[i] = (High[iHighest(NULL,0,MODE_HIGH,depth,i)]+buffer1[i+1])/2.0;
         if (Low[i] < buffer3[i+1])
               buffer3[i] =  Low[i];
         else  buffer3[i] = (Low[iLowest(NULL,0,MODE_LOW,depth,i)]+buffer3[i+1])/2.0;
               buffer2[i] = (buffer1[i]+buffer3[i])/2.0;
   }
   return(0);
}

limit = MathMax(limit,MathMin(Bars-1,iCustom(NULL,timeFrame,indicatorFileName,"returnBars",0,0)*timeFrame/Period()));
for(i=limit; i>=0; i--)
{
int y      = iBarShift(NULL,timeFrame,Time[i]);
buffer1[i] = iCustom(NULL,timeFrame,indicatorFileName,"calculateCfb",CfbDepth,CfbPrice,CfbNormalizePeriod,CfbSmooth,CfbResultSmooth,CfbResultSmoothPhase,CfbResultSmoothDouble,Depth1,Depth2,0,y);
buffer2[i] = iCustom(NULL,timeFrame,indicatorFileName,"calculateCfb",CfbDepth,CfbPrice,CfbNormalizePeriod,CfbSmooth,CfbResultSmooth,CfbResultSmoothPhase,CfbResultSmoothDouble,Depth1,Depth2,1,y);
buffer3[i] = iCustom(NULL,timeFrame,indicatorFileName,"calculateCfb",CfbDepth,CfbPrice,CfbNormalizePeriod,CfbSmooth,CfbResultSmooth,CfbResultSmoothPhase,CfbResultSmoothDouble,Depth1,Depth2,2,y);



      if (timeFrame <= Period() || y==iBarShift(NULL,timeFrame,Time[i-1])) continue;
      if (!Interpolate) continue;

      //
      //
      //
      //
      //

      datetime time = iTime(NULL,timeFrame,y);
      for(int nn = 1; i+n < Bars && Time[i+nn] >= time; nn++) continue;	
      for(k = 1; k < nn; k++)
      {
      buffer1[i+k] = buffer1[i] + (buffer1[i+nn] - buffer1[i])*k/nn;
      buffer2[i+k] = buffer2[i] + (buffer2[i+nn] - buffer2[i])*k/nn;
      buffer3[i+k] = buffer3[i] + (buffer3[i+nn] - buffer3[i])*k/nn;
      }               
   }
return(0);
}


string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int    iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};

//
//
//
//
//

int stringToTimeFrame(string tfs)
{
   tfs = StringUpperCase(tfs);
   for (int i=ArraySize(iTfTable)-1; i>=0; i--)
         if (tfs==sTfTable[i] || tfs==""+iTfTable[i]) return(MathMax(iTfTable[i],Period()));
                                                      return(Period());
}
string timeFrameToString(int tf)
{
   for (int i=ArraySize(iTfTable)-1; i>=0; i--) 
         if (tf==iTfTable[i]) return(sTfTable[i]);
                              return("");
}

//
//
//
//
//

string StringUpperCase(string str)
{
   string   s = str;

   for (int length=StringLen(str)-1; length>=0; length--)
   {
      int tchar = StringGetChar(s, length);
         if((tchar > 96 && tchar < 123) || (tchar > 223 && tchar < 256))
                     s = StringSetChar(s, length, tchar - 32);
         else if(tchar > -33 && tchar < 0)
                     s = StringSetChar(s, length, tchar + 224);
   }
   return(s);
}   
 
//
//
//
//

int    Depths[] = {2,3,4,6,8,12,16,24,32,48,64,96,128,192};
double workCfb[][28];

//
//
//
//
//

double iCfb(int totalBars, double price, int depth, int smooth, int i)
{
   if (ArrayRange(workCfb,0) != totalBars) ArrayResize(workCfb,totalBars);
         
   //
   //
   //
   //
   //

   double suma     = 0;
   double sumb     = 0;
   double cfb      = 0;
   double evenCoef = 1;
   double oddCoef  = 1;
   double avg      = 0;
         
      if (i>=smooth)
         for (int k=depth-1; k>=0; k--)
         {
            workCfb[i][k]    = iCfbFunc(totalBars,price,i,Depths[k],k);
            workCfb[i][k+14] = workCfb[i-1][k+14] + (workCfb[i][k]-workCfb[i-smooth][k])/smooth;

                  if ((k%2)==0)
                        { avg = oddCoef  * workCfb[i][k+14]; oddCoef  = oddCoef  * (1 - avg); }
                  else  { avg = evenCoef * workCfb[i][k+14]; evenCoef = evenCoef * (1 - avg); }
               
               suma += avg*avg*Depths[k];
               sumb += avg;
         }
      else for (k=depth-1; k>=0; k--) { workCfb[i][k] = 0; workCfb[i][k+14] = 0; }            

   //
   //
   //
   //
   //

   if (sumb != 0) cfb = suma/sumb;
   return(cfb);
}

//+------------------------------------------------------------------
//|                                                                  
//+------------------------------------------------------------------
//
//
//
//
//

double  workCfbFunc[][70];
#define _prices 0
#define _roc    1
#define _value1 2
#define _value2 3
#define _value3 4

//
//
//
//

double iCfbFunc(int totalBars, double price, int r, int depth, int k)
{
   k *= 5;
      if (ArrayRange(workCfbFunc,0) != totalBars) ArrayResize(workCfbFunc,totalBars);
      if (r<=(depth+1))
      {
         workCfbFunc[r][k+_prices] = 0;
         workCfbFunc[r][k+_roc]    = 0;
         workCfbFunc[r][k+_value1] = 0;
         workCfbFunc[r][k+_value2] = 0;
         workCfbFunc[r][k+_value3] = 0;
         return(0);
      }         
      workCfbFunc[r][k+_prices] = price; 

   //
   //
   //
   //
   //

      workCfbFunc[r][k+_roc]    = MathAbs(workCfbFunc[r][k+_prices] - workCfbFunc[r-1][k+_prices]);
      workCfbFunc[r][k+_value1] = workCfbFunc[r-1][k+_value1] - workCfbFunc[r-depth][k+_roc] + workCfbFunc[r][k+_roc];
      workCfbFunc[r][k+_value2] = workCfbFunc[r-1][k+_value2] - workCfbFunc[r-1][k+_value1] + workCfbFunc[r][k+_roc]*depth;
      workCfbFunc[r][k+_value3] = workCfbFunc[r-1][k+_value3] - workCfbFunc[r-1-depth][k+_prices] + workCfbFunc[r-1][k+_prices];
   
      double dividend = MathAbs(depth*workCfbFunc[r][k+_prices]-workCfbFunc[r][k+_value3]);

      //
      //
      //
      //
      //
         
   if (workCfbFunc[r][k+_value2] != 0)
         return( dividend / workCfbFunc[r][k+_value2]);
   else  return(0.00);            
}

//+------------------------------------------------------------------
//|                                                                  
//+------------------------------------------------------------------
//
//
//
//
//

double wrk[][20];

#define bsmax  5
#define bsmin  6
#define volty  7
#define vsum   8
#define avolty 9

//
//
//
//
//

double iDSmooth(double price, double length, double phase, bool isDouble, int i, int s=0)
{
   if (isDouble)
         return (iSmooth(iSmooth(price,MathSqrt(length),phase,i,s),MathSqrt(length),phase,i,s+10));
   else  return (iSmooth(price,length,phase,i,s));
}

//
//
//
//
//

double iSmooth(double price, double length, double phase, int i, int s=0)
{
   if (length <=1) return(price);
   if (ArrayRange(wrk,0) != Bars) ArrayResize(wrk,Bars);
   
   int r = Bars-i-1; 
      if (r==0) { for(int k=0; k<7; k++) wrk[r][k+s]=price; for(; k<10; k++) wrk[r][k+s]=0; return(price); }

   //
   //
   //
   //
   //
   
      double len1   = MathMax(MathLog(MathSqrt(0.5*(length-1)))/MathLog(2.0)+2.0,0);
      double pow1   = MathMax(len1-2.0,0.5);
      double del1   = price - wrk[r-1][bsmax+s];
      double del2   = price - wrk[r-1][bsmin+s];
      double div    = 1.0/(10.0+10.0*(MathMin(MathMax(length-10,0),100))/100);
      int    forBar = MathMin(r,10);
	
         wrk[r][volty+s] = 0;
               if(MathAbs(del1) > MathAbs(del2)) wrk[r][volty+s] = MathAbs(del1); 
               if(MathAbs(del1) < MathAbs(del2)) wrk[r][volty+s] = MathAbs(del2); 
         wrk[r][vsum+s] =	wrk[r-1][vsum+s] + (wrk[r][volty+s]-wrk[r-forBar][volty+s])*div;
         
         //
         //
         //
         //
         //
   
         wrk[r][avolty+s] = wrk[r-1][avolty+s]+(2.0/(MathMax(4.0*length,30)+1.0))*(wrk[r][vsum+s]-wrk[r-1][avolty+s]);
            if (wrk[r][avolty+s] > 0)
               double dVolty = wrk[r][volty+s]/wrk[r][avolty+s]; else dVolty = 0;   
	               if (dVolty > MathPow(len1,1.0/pow1)) dVolty = MathPow(len1,1.0/pow1);
                  if (dVolty < 1)                      dVolty = 1.0;

      //
      //
      //
      //
      //
	        
   	double pow2 = MathPow(dVolty, pow1);
      double len2 = MathSqrt(0.5*(length-1))*len1;
      double Kv   = MathPow(len2/(len2+1), MathSqrt(pow2));

         if (del1 > 0) wrk[r][bsmax+s] = price; else wrk[r][bsmax+s] = price - Kv*del1;
         if (del2 < 0) wrk[r][bsmin+s] = price; else wrk[r][bsmin+s] = price - Kv*del2;
	
   //
   //
   //
   //
   //
      
      double R     = MathMax(MathMin(phase,100),-100)/100.0 + 1.5;
      double beta  = 0.45*(length-1)/(0.45*(length-1)+2);
      double alpha = MathPow(beta,pow2);

         wrk[r][0+s] = price + alpha*(wrk[r-1][0+s]-price);
         wrk[r][1+s] = (price - wrk[r][0+s])*(1-beta) + beta*wrk[r-1][1+s];
         wrk[r][2+s] = (wrk[r][0+s] + R*wrk[r][1+s]);
         wrk[r][3+s] = (wrk[r][2+s] - wrk[r-1][4+s])*MathPow((1-alpha),2) + MathPow(alpha,2)*wrk[r-1][3+s];
         wrk[r][4+s] = (wrk[r-1][4+s] + wrk[r][3+s]); 

   //
   //
   //
   //
   //

   return(wrk[r][4+s]);
}