//+------------------------------------------------------------------+
//|                                                          ASI.mq4 |
//+------------------------------------------------------------------+
#property indicator_separate_window
#property indicator_buffers 4
#property indicator_color1  PaleVioletRed
#property indicator_color2  DeepSkyBlue
#property indicator_color3  DimGray
#property indicator_color4  LimeGreen
#property indicator_style3  STYLE_DOT
#property indicator_width4  2

//
//
//
//
//

#import "dynamicZone.dll"
   double dzBuyP(double& sourceArray[],double probabiltyValue, int lookBack, int bars, int i,double precision);
   double dzSellP(double& sourceArray[],double probabiltyValue, int lookBack, int bars, int i,double precision);
#import

//
//
//
//
//

extern string ForSymbol              = "";
extern double T                      = 300.0;
extern int    SmoothLength           = 9;
extern double SmoothPhase            = -100;
extern int    DzLookBackBars         = 70;
extern double DzStartBuyProbability  = 0.15;
extern double DzStartSellProbability = 0.15;

double ASIBuffer[];
double SIBuffer[];
double sli[];
double bli[];
double zli[];
   
//
//
//
//
//

string indicatorFileName;
bool   returnBars;
bool   calculateValue;
   
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int init()
{
   IndicatorBuffers(5);
   SetIndexBuffer(0,bli);
   SetIndexBuffer(1,sli);
   SetIndexBuffer(2,zli);
   SetIndexBuffer(3,ASIBuffer); SetIndexEmptyValue(3, 0.0); SetIndexLabel(3, "Accumulation Swing Index");
   SetIndexBuffer(4,SIBuffer);  SetIndexEmptyValue(4, 0.0);

   //
   //
   //
   //
   //
      
   indicatorFileName = WindowExpertName();
   calculateValue    = (ForSymbol=="calculateValue"); if (calculateValue) return(0);
   returnBars        = (ForSymbol=="returnBars");     if (returnBars)     return(0);
                    if (ForSymbol=="") ForSymbol=Symbol();

      IndicatorShortName(ForSymbol+" Accumulation Swing Index ("+DoubleToStr(T,2)+")");
   return(0);
}
int deinit() { return(0); }

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int start()
{
   int i, limit, counted_bars = IndicatorCounted();

   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
         limit = MathMin(Bars-counted_bars,Bars-1);
         if (returnBars) { ASIBuffer[0] = limit+1; return(0); }

   //
   //
   //
   //
   //
   
   if (calculateValue || ForSymbol==Symbol())
   {
      double R, K, TR, ER, SH;
//      double Tpoints = T*MarketInfo(Symbol(), MODE_POINT);
      
      //
      //
      //
      //
      //
      
      for(i = limit; i >= 0; i--)
      {
         TR = iATR(Symbol(), 0, 1, i);
         
         if(Close[i+1] >= Low[i] && Close[i+1] <= High[i]) 
            ER = 0; 
         else 
            {
               if(Close[i+1] > High[i]) ER = MathAbs(High[i] - Close[i+1]);
               if(Close[i+1] < Low[i])  ER = MathAbs(Low[i] - Close[i+1]);
            }
         K  = MathMax(MathAbs(High[i] - Close[i+1]), MathAbs(Low[i] - Close[i+1]));
         SH = MathAbs(Close[i+1] - Open[i+1]);
         R  = TR - 0.5*ER + 0.25*SH;
         if (R == 0) 
               SIBuffer[i] = iSmooth(0,SmoothLength,SmoothPhase,i,0); 
         else  SIBuffer[i] = iSmooth(50*(Close[i] - Close[i+1] + 0.5*(Close[i] - Open[i]) +  0.25*(Close[i+1] - Open[i+1]))*(K / T) / R,SmoothLength,SmoothPhase,i,0); 
         
              ASIBuffer[i] = iSmooth(ASIBuffer[i+1] + SIBuffer[i],SmoothLength,SmoothPhase,i,10);
              bli[i]     = dzBuyP (ASIBuffer, DzStartBuyProbability,  DzLookBackBars, Bars, i,0.0001);
              sli[i]     = dzSellP(ASIBuffer, DzStartSellProbability, DzLookBackBars, Bars, i,0.0001);
              zli[i]     = dzSellP(ASIBuffer, 0.5,                    DzLookBackBars, Bars, i,0.0001);
      }
      return(0);
   }

   //
   //
   //
   //
   //
   
   limit = MathMax(limit,MathMin(Bars-1,iCustom(ForSymbol,0,indicatorFileName,"returnBars",0,0)));
   for(i=limit; i>=0; i--)
   {
      int y = iBarShift(ForSymbol,0,Time[i]);
            bli[i]       = iCustom(ForSymbol,0,indicatorFileName,"calculateValue",T,SmoothLength,SmoothPhase,DzLookBackBars,DzStartBuyProbability,DzStartSellProbability,0,y);
            sli[i]       = iCustom(ForSymbol,0,indicatorFileName,"calculateValue",T,SmoothLength,SmoothPhase,DzLookBackBars,DzStartBuyProbability,DzStartSellProbability,1,y);
            zli[i]       = iCustom(ForSymbol,0,indicatorFileName,"calculateValue",T,SmoothLength,SmoothPhase,DzLookBackBars,DzStartBuyProbability,DzStartSellProbability,2,y);
            ASIBuffer[i] = iCustom(ForSymbol,0,indicatorFileName,"calculateValue",T,SmoothLength,SmoothPhase,DzLookBackBars,DzStartBuyProbability,DzStartSellProbability,3,y);
   }
   return(0);
}


double wrk[][20];
#define bsmax  5
#define bsmin  6
#define volty  7
#define vsum   8
#define avolty 9

//
//
//
//
//

double iSmooth(double price, double length, double phase, int i, int s=0)
{
   if (ArrayRange(wrk,0) != Bars) ArrayResize(wrk,Bars);
   
   int r = Bars-i-1; 
      if (r==0) { for(int k=0; k<7; k++) wrk[0][k+s]=price; for(; k<10; k++) wrk[0][k+s]=0; return(price); }

   //
   //
   //
   //
   //
   
      double len1   = MathMax(MathLog(MathSqrt(0.5*(length-1)))/MathLog(2.0)+2.0,0);
      double pow1   = MathMax(len1-2.0,0.5);
      double del1   = price - wrk[r-1][bsmax+s];
      double del2   = price - wrk[r-1][bsmin+s];
      double div    = 1.0/(10.0+10.0*(MathMin(MathMax(length-10,0),100))/100);
      int    forBar = MathMin(r,10);
	
         wrk[r][volty+s] = 0;
               if(MathAbs(del1) > MathAbs(del2)) wrk[r][volty+s] = MathAbs(del1); 
               if(MathAbs(del1) < MathAbs(del2)) wrk[r][volty+s] = MathAbs(del2); 
         wrk[r][vsum+s] =	wrk[r-1][vsum+s] + (wrk[r][volty+s]-wrk[r-forBar][volty+s])*div;
         
         //
         //
         //
         //
         //
   
         wrk[r][avolty+s] = wrk[r-1][avolty+s]+(2.0/(MathMax(4.0*length,30)+1.0))*(wrk[r][vsum+s]-wrk[r-1][avolty+s]);
            if (wrk[r][avolty+s] > 0)
               double dVolty = wrk[r][volty+s]/wrk[r][avolty+s]; else dVolty = 0;   
	               if (dVolty > MathPow(len1,1.0/pow1)) dVolty = MathPow(len1,1.0/pow1);
                  if (dVolty < 1)                      dVolty = 1.0;

      //
      //
      //
      //
      //
	        
   	double pow2 = MathPow(dVolty, pow1);
      double len2 = MathSqrt(0.5*(length-1))*len1;
      double Kv   = MathPow(len2/(len2+1), MathSqrt(pow2));

         if (del1 > 0) wrk[r][bsmax+s] = price; else wrk[r][bsmax+s] = price - Kv*del1;
         if (del2 < 0) wrk[r][bsmin+s] = price; else wrk[r][bsmin+s] = price - Kv*del2;
	
   //
   //
   //
   //
   //
      
      double R     = MathMax(MathMin(phase,100),-100)/100.0 + 1.5;
      double beta  = 0.45*(length-1)/(0.45*(length-1)+2);
      double alpha = MathPow(beta,pow2);

         wrk[r][0+s] = price + alpha*(wrk[r-1][0+s]-price);
         wrk[r][1+s] = (price - wrk[r][0+s])*(1-beta) + beta*wrk[r-1][1+s];
         wrk[r][2+s] = (wrk[r][0+s] + R*wrk[r][1+s]);
         wrk[r][3+s] = (wrk[r][2+s] - wrk[r-1][4+s])*MathPow((1-alpha),2) + MathPow(alpha,2)*wrk[r-1][3+s];
         wrk[r][4+s] = (wrk[r-1][4+s] + wrk[r][3+s]); 

   //
   //
   //
   //
   //

   return(wrk[r][4+s]);
}