//+------------------------------------------------------------------+
//|                                                 Jim Sloman's ndx |
//|                                                      ocn ndx.mq4 |
//|                                                           mladen |
//+------------------------------------------------------------------+
#property copyright "mladen"
#property link      "mladenfx@gmail.com"

#property indicator_separate_window
#property indicator_buffers 4
#property indicator_color1  DimGray
#property indicator_color2  DimGray
#property indicator_color3  DimGray
#property indicator_color4  DeepSkyBlue
#property indicator_style1  STYLE_DOT
#property indicator_style2  STYLE_DOT
#property indicator_style3  STYLE_DOT

//
//
//
//
//

extern string _               =  "NDX settings";
extern int    NDX_Period      =  40;
extern int    NDX_TEMA_Period =  20;
extern int    NDX_Price       =  PRICE_CLOSE;
extern string __              =  "NST settings";
extern int    NST_Period      =  20;
extern int    NST_TEMA_Period =  10;
extern string ___             =  "Levels settings";
extern int    OverBought      =  50;
extern int    OverSold        = -50; 

//
//
//
//
//

double nxc[];
double obLine[];
double osLine[];
double zeroLine[];
double tBuffer[][7];
double alphaNdx;
double alphaNst;

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int init()
{
   SetIndexBuffer(0,zeroLine); SetIndexLabel(0,NULL);
   SetIndexBuffer(1,obLine);   SetIndexLabel(1,NULL);
   SetIndexBuffer(2,osLine);   SetIndexLabel(2,NULL);
   SetIndexBuffer(3,nxc);

   //
   //
   //
   //
   //
   
   string PriceType;
      switch(NDX_Price)
      {
         case PRICE_CLOSE:    PriceType = "Close";    break;  // 0
         case PRICE_OPEN:     PriceType = "Open";     break;  // 1
         case PRICE_HIGH:     PriceType = "High";     break;  // 2
         case PRICE_LOW:      PriceType = "Low";      break;  // 3
         case PRICE_MEDIAN:   PriceType = "Median";   break;  // 4
         case PRICE_TYPICAL:  PriceType = "Typical";  break;  // 5
         case PRICE_WEIGHTED: PriceType = "Weighted"; break;  // 6
      }      

   //
   //
   //
   //
   //

   NDX_TEMA_Period = MathMax(NDX_TEMA_Period,1);
   NDX_Period      = MathMax(NDX_Period ,1);
   NST_TEMA_Period = MathMax(NST_TEMA_Period,1);
   NST_Period      = MathMax(NST_Period ,1);
     alphaNdx = 2.0 /(1.0 + NDX_TEMA_Period);
     alphaNst = 2.0 /(1.0 + NST_TEMA_Period);
           
   IndicatorShortName ("nxc (ndx: "+NDX_Period+","+NDX_TEMA_Period+","+PriceType+") (nst: "+NST_Period+","+NST_TEMA_Period+")");
   return(0);
}
int deinit()
{
   return(0);
}

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

#define iPrc 6

//
//
//
//
//

int start()
{
   int    counted_bars=IndicatorCounted();
   int    i,k,r,limit;

   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
         limit = MathMin(Bars-counted_bars,Bars-NDX_Period-1);
         limit = MathMin(limit            ,Bars-NST_Period-1);
         if (ArrayRange(tBuffer,0) != Bars) ArrayResize(tBuffer,Bars);

   //
   //
   //
   //
   //

   for(i=limit, r=Bars-i-1; i >= 0; i--,r++)
   {
      double currPrice = iMA(NULL,0,1,0,MODE_SMA,NDX_Price,i);
         if (currPrice > 0)
               tBuffer[r][iPrc] = MathLog(currPrice);
         else  tBuffer[r][iPrc] = 0.00;
      
      //
      //
      //
      //
      //

         double sumMom = 0;
         double sumDen = 0;
         double sumDif = 0;

            for (k=1; k < NDX_Period; k++)
            {
               sumDif += MathAbs(tBuffer[r-k+1][iPrc]-tBuffer[r-k][iPrc]);
               if (sumDif !=0)
                     double stoch = (tBuffer[r][iPrc]-tBuffer[r-k][iPrc])/sumDif;
               else         stoch = 0;
               double coeff = 1.0/MathSqrt(k);
          
               sumMom += coeff*stoch;
               sumDen += coeff;
            }
         
            double ndxTemp = iTema(100.0*sumMom/sumDen,alphaNdx,0,r);
               if (ndxTemp > 90) ndxTemp =  90+( ndxTemp-90)/2.0;
               if (ndxTemp <-90) ndxTemp = -90-(-ndxTemp-90)/2.0;

      //
      //
      //   
      //
      //
      
         double max    = High[i];
         double min    = Low[i];
         double sumSto = 0;
      
            for (k=0, sumDen=0; k < NST_Period; k++)
            {
               if (max < High[i+k]) max = High[i+k];
               if (min >  Low[i+k]) min =  Low[i+k];
               if (max!=min)
                     stoch = (Close[i]-min)/(max-min);
               else  stoch = 0;
               coeff = 1.0/MathSqrt(k+1.0);
          
               sumSto += coeff*stoch;
               sumDen += coeff;
            }

            double nstTemp = iTema((200.0*sumSto/sumDen)-100.0,alphaNst,3,r);
               if (nstTemp > 85) nstTemp =  85+( nstTemp-85)/2.0;
               if (nstTemp <-85) nstTemp = -85-(-nstTemp-85)/2.0;

      //
      //
      //
      //
      //
      
         double nxcTemp = ((MathAbs(ndxTemp)*nstTemp)+(MathAbs(nstTemp)*ndxTemp))/2.0;
            if (nxcTemp>0)
                  nxcTemp = MathSqrt(nxcTemp);
            else  nxcTemp = MathSqrt(MathAbs(nxcTemp))*(-1);

         nxc[i]      = nxcTemp;
         obLine[i]   = OverBought;
         osLine[i]   = OverSold;
         zeroLine[i] = 0;
   }
   return(0);
}


//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

double iTema(double price,double alpha,int sbuf,int i)
{
   if (i < 1)
      {
         tBuffer[i][sbuf+0] = price;
         tBuffer[i][sbuf+1] = price;
         tBuffer[i][sbuf+2] = price;
      }
   else
      {
         tBuffer[i][sbuf+0] = tBuffer[i-1][sbuf+0]+alpha*(price             -tBuffer[i-1][sbuf+0]);
         tBuffer[i][sbuf+1] = tBuffer[i-1][sbuf+1]+alpha*(tBuffer[i][sbuf+0]-tBuffer[i-1][sbuf+1]);
         tBuffer[i][sbuf+2] = tBuffer[i-1][sbuf+2]+alpha*(tBuffer[i][sbuf+1]-tBuffer[i-1][sbuf+2]);
      }
   return(3.0*tBuffer[i][sbuf+0] - 3.0*tBuffer[i][sbuf+1] + tBuffer[i][sbuf+2]);
}