Code: Select all

{
	TASC JUNE 2026
	One Percent A Week: A High-Probability Weekly 
	Trading Strategy For TQQQ
	Part 2: Variations And Community Enhancements
	Dion Kurczek
}

inputs:
	FirstDayStrengthPct( 2.0 ),
	NextDayWeakPct( 3.0 ),
	TargetMult( 1.07 ),
	ExpansionTriggerPct( 0.3 ),
	ExpansionMult( 1.011 ),
	RecoveryExitMult( 1.025 ),
	LossArmPct( -1.3 ),
	HardLossMult( 0.985 );

variables:
	DayOfTradeWeek( 0 ),
	EntryDayOfTradeWeek( 0 ),
	ProfitPct( 0 ),
	TargetPrice( 0 ),
	FirstDayStrong( false ),
	MP( 0 );

MP = MarketPosition;

if CurrentBar = 1 then
begin
	DayOfTradeWeek = 1;
	EntryDayOfTradeWeek = 0;
	FirstDayStrong = false;
end
else
begin
	if DayOfWeek( Date ) < DayOfWeek( Date[1] ) then
	begin
		DayOfTradeWeek = 1;
		EntryDayOfTradeWeek = 0;
		FirstDayStrong = false;
	end
	else if Date <> Date[1] then
		DayOfTradeWeek = DayOfTradeWeek[1] + 1
	else
		DayOfTradeWeek = DayOfTradeWeek[1];
end;

if MP = 0 and DayOfWeek( Date ) <> 1 
 and DayOfWeek( Date Next Bar ) = 1 then
begin
	Buy ( "WeekIn" ) next bar at market;
end
else if MP = 1 then
begin
	if MP[1] <> 1 then
	begin
		EntryDayOfTradeWeek = DayOfTradeWeek;
		FirstDayStrong = false;
	end;

	ProfitPct = 100 * ( ( Close / EntryPrice ) - 1 );

	if DayOfTradeWeek = EntryDayOfTradeWeek 
	 and ProfitPct > FirstDayStrengthPct then
		FirstDayStrong = true;

	if DayOfTradeWeek = EntryDayOfTradeWeek + 1 and
	   FirstDayStrong and
	   ProfitPct < NextDayWeakPct then
		Sell ( "MomFail" ) next bar at market
	else if ProfitPct <= LossArmPct then
		Sell ( "HardLoss" ) next bar 
		 at EntryPrice * HardLossMult stop
	else if ProfitPct > 0 then
	begin
		TargetPrice = EntryPrice * TargetMult;

		if ProfitPct > ExpansionTriggerPct then
			TargetPrice = TargetPrice * ExpansionMult;

		Sell ( "Target" ) next bar at TargetPrice limit;
	end
	else if DayOfTradeWeek > EntryDayOfTradeWeek 
	 and Close < Open then
		Sell ( "Recovery" ) next bar 
		 at EntryPrice * RecoveryExitMult limit
	else if DayOfTradeWeek > EntryDayOfTradeWeek then
		Sell ( "BrkEven" ) next bar at EntryPrice limit;

	if DayOfWeek( Date ) = 5 then
		SetExitOnClose;
end;